函数参考


GUICtrlCreateButton

在GUI上创建一个按钮控件.

GUICtrlCreateButton ( "文本", 左侧, 顶部 [, 宽度 [, 高度 [, 样式 [, 扩展样式]]]] )

参数

文本 按钮控件显示的文本.
左侧 控件左侧的位置.若此值为 -1 则根据 GUICoordMode 的设置来计算左侧位置.
顶部 控件上方的位置.若此值为 -1 则根据 GUICoordMode 的设置来计算上方位置.
宽度 [可选参数] 控件的宽度(默认值(default)为上一个控件的宽度).
高度 [可选参数] 控件的高度(默认值(default)为上一个控件的高度).
样式 [可选参数] 指定控件的样式.请查看附录中关于 GUI 控件样式 的说明.

默认(default) ( -1) : 无.
强制样式: $WS_TABSTOP
扩展样式 [可选参数] 指定控件的扩展样式.请查看附录的 扩展样式表 .

返回值

成功: 返回控件标识符(控件ID).
失败: 返回值为0.

注意/说明

要设置或者修改控件信息,请参考 GUICtrlUpdate....

使用 $BS_ICON 或 $BS_BITMAP 样式即可让按钮显示一个图标或图片.使用 GUICtrlSetImage 来指定图片文件.

要在默认样式的基础上添加一个新的样式可使用 BitOr($GUI_SS_DEFAULT_BUTTON, 新样式,...).

要使用上方指定的值,您必须包含 #include <ButtonConstants.au3> 在你的脚本.

默认(default)大小为: $GUI_DOCKSIZE

相关

GUICoordMode (Option), GUICtrlUpdate..., GUIGetMsg

示例/演示


#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $Button_1, $Button_2, $msg
    GUICreate("My GUI Button") ; 创建一个对话框,并居中显示

    Opt("GUICoordMode", 2)
    $Button_1 = GUICtrlCreateButton("打开记事本", 10, 30, 100)
    $Button_2 = GUICtrlCreateButton("测试按钮", 0, -1)

    GUISetState()      ; 显示有两个按钮的对话框

    ; 运行界面,直到窗口被关闭
    While 1
        $msg = GUIGetMsg()
        Select
            Case $msg = $GUI_EVENT_CLOSE
                ExitLoop
            Case $msg = $Button_1
                Run('Notepad.exe')    ; 点击按钮 1 打开记事本
            Case $msg = $Button_2
                MsgBox(4096, '测试', '你点击了测试按钮')    ; 点击按钮 2 显示一个简单的对话框
        EndSelect
    WEnd
EndFunc   ;==>Example