函数参考

GUICtrlCreateInput

在GUI上创建一个输入框(Input)控件.

GUICtrlCreateInput ( "文本", 左侧, 顶部 [, 宽度 [, 高度 [, 样式 [, 扩展样式]]]] )

参数

文本 输入框(Input)控件显示的文本.
左侧 控件左侧的位置.若此值为 -1 则根据 GUICoordMode 的设置来计算左侧位置.
顶部 控件上方的位置.若此值为 -1 则根据 GUICoordMode 的设置来计算上方位置.
宽度 [可选参数] 控件的宽度(默认值(default)为上一个控件的宽度).
高度 [可选参数] 控件的高度(默认值(default)为上一个控件的高度).
样式 [可选参数] 指定控件的样式.请查看附录中关于 GUI 控件样式 的说明.

默认值(default)(-1): $ES_LEFT, $ES_AUTOHSCROLL
强制样式: $WS_TABSTOP 和 $ES_MULTILINE 将被重设.(如果非只读$ES_READONLY)
扩展样式 [可选参数] 指定控件的扩展样式.请查看附录的 扩展样式表.

返回值

成功: 返回新控件的控件标识符(控件ID).
失败: 返回值为0.

注意/说明

若要获得控件的各种值,请参考 GUICtrlRead.
要设置或者修改控件信息,请参考 GUICtrlUpdate....

若要定义一个用于输入密码的(输入的字符将被星号隐藏)输入框控件则请使用 $ES_PASSWORD 样式.

若要使创建的控件支持文件拖放则请在使用 GUICreate() 创建窗口时添加 WS_EX_ACCEPTFILES 扩展样式 并设置该控件的状态为 $GUI_DROPACCEPTED .
拖动多个文件会被"|"分割开,你可以使用GuiCtrlRead来读取数据.

要使用上方指定的值,您必须包含 #include <EditConstants.au3> 在您的脚本.

默认大小为: $GUI_DOCKHEIGHT.

相关

GUICoordMode (Option), GUICtrlUpdate..., GUIGetMsg, GUICtrlRead, GUICtrlCreateUpdown, GUICtrlSetLimit

示例/演示


#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $file, $btn, $msg

    GUICreate(" My GUI input acceptfile", 320, 120, @DesktopWidth / 2 - 160, @DesktopHeight / 2 - 45, -1, 0x00000018); WS_EX_ACCEPTFILES
    $file = GUICtrlCreateInput("", 10, 5, 300, 20)
    GUICtrlSetState(-1, $GUI_DROPACCEPTED)
    GUICtrlCreateInput("", 10, 35, 300, 20) ; will not accept drag&drop files
    $btn = GUICtrlCreateButton("Ok", 40, 75, 60, 20)

    GUISetState()

    $msg = 0
    While $msg <> $GUI_EVENT_CLOSE
        $msg = GUIGetMsg()
        Select
            Case $msg = $btn
                ExitLoop
        EndSelect
    WEnd

    MsgBox(4096, "drag drop file", GUICtrlRead($file))
EndFunc   ;==>Example