函数参考

GUICtrlCreateTab

在GUI上创建一个标签页(Tab)控件.

GUICtrlCreateTab ( 左侧, 顶部 [, 宽度 [, 高度 [, 样式 [, 扩展样式]]]] )

 

参数

左侧 控件左侧的位置.若此值为 -1 则根据 GUICoordMode 的设置来计算左侧位置.
顶部 控件上方的位置.若此值为 -1 则根据 GUICoordMode 的设置来计算上方位置.
宽度 [可选参数] 控件的宽度(默认值(default)为上一个控件的宽度).
高度 [可选参数] 控件的高度(默认值(default)为上一个控件的高度).
样式 [可选参数] 指定控件的样式.请查看附录中关于 GUI 控件样式 的说明.

默认值(default)(-1):无
强制性样式: $WS_TABSTOP, $WS_CLIPSIBLINGS
扩展样式 [可选参数] 指定控件的扩展样式.请查看附录的 扩展样式表.

 

返回值

成功: 返回新控件的控件标识符(控件ID).
失败: 返回值为0.

 

注意/说明

本函数只是创建了一个标签控件(容器),我们要在其中创建标签项,之后还要使用 GUICtrlCreate... 来创建每个标签项的关联控件.

要设置或者修改控件信息,请参考 GUICtrlUpdate....

要在默认样式的基础上添加一个新的样式可使用 BitOr($GUI_SS_DEFAULT_TAB, 新样式,...).

要使用上方指定的值,您必须包含 #include <TabConstants.au3> 在你的脚本中.

默认大小为: $GUI_DOCKSIZE.

窗口里面只能创建一个标签控件.但是一个脚本中可以使用标签创建许多窗口.

 

相关

GUICtrlCreateTabItem, GUICoordMode (Option), GUICtrlCreate..., GUICtrlUpdate..., GUIGetMsg

 

示例/演示


#include <GUIConstantsEx.au3>

Opt('MustDeclareVars', 1)

Example()

Func Example()
    Local $tab, $tab0, $tab0OK, $tab0input
    Local $tab1, $tab1combo, $tab1OK
    Local $tab2, $tab2OK, $msg
   
    GUICreate("My GUI Tab")  ; will create a dialog box that when displayed is centered

    GUISetBkColor(0x00E0FFFF)
    GUISetFont(9, 300)

    $tab = GUICtrlCreateTab(10, 10, 200, 100)

    $tab0 = GUICtrlCreateTabItem("tab0")
    GUICtrlCreateLabel("label0", 30, 80, 50, 20)
    $tab0OK = GUICtrlCreateButton("OK0", 20, 50, 50, 20)
    $tab0input = GUICtrlCreateInput("default", 80, 50, 70, 20)

    $tab1 = GUICtrlCreateTabItem("tab----1")
    GUICtrlCreateLabel("label1", 30, 80, 50, 20)
    $tab1combo = GUICtrlCreateCombo("", 20, 50, 60, 120)
    GUICtrlSetData(-1, "Trids|CyberSlug|Larry|Jon|Tylo", "Jon") ; default Jon
    $tab1OK = GUICtrlCreateButton("OK1", 80, 50, 50, 20)

    $tab2 = GUICtrlCreateTabItem("tab2")
    GUICtrlSetState(-1, $GUI_SHOW)  ; will be display first
    GUICtrlCreateLabel("label2", 30, 80, 50, 20)
    $tab2OK = GUICtrlCreateButton("OK2", 140, 50, 50)

    GUICtrlCreateTabItem("")    ; end tabitem definition

    GUICtrlCreateLabel("label3", 20, 130, 50, 20)

    GUISetState()

    ; Run the GUI until the dialog is closed
    While 1
        $msg = GUIGetMsg()
       
        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
EndFunc   ;==>Example