函数参考

GUICtrlCreateTabItem

在GUI上创建一个标签页控件项目.

GUICtrlCreateTabItem ( "文本" )

 

参数

文本 控件显示的文本.

 

返回值

成功: 返回新控件的控件标识符(控件ID).
失败: 返回值为0.

 

注意/说明

要设置或者修改控件信息,请参考 GUICtrlUpdate....

若要让指定的标签页在对话框(窗口)打开的时候先被显示则请参考下面的示例使用语句 GUICtrlSetState(-1,$GUI_SHOW).参考例子.

若要结束标签控件的定义则只需在最后创建一个空文本的"标签项"即可.这个"标签项"将不被绘制(代码太多了 ...)

当使用高级模式, GUICtrlRead($tab,1) 将会返回控件ID代替点击的标签项目的索引.

要创建一个新的控件到一个存在的标签项目上,使用 GUISwitch($hWin,$tabitem) 选择标签并创建您的新控件. 别忘了使用 GUICtrlCreateTabItem("") 关闭标签项目.

 

相关

GUICtrlSetState, GUISwitch, GUIGetMsg, GUICtrlRead, GUIEventOptions (Option), GUICtrlCreateTab

 

示例/演示


#include <GUIConstantsEx.au3>

Opt('MustDeclareVars', 1)

Example()

Func Example()
    Local $tab, $tab0, $tab0OK, $tab0input
    Local $tab1, $tab1combo, $tab1OK
    Local $tab2, $tab2OK, $msg
   
    GUICreate("My GUI Tab", 250, 150); will create a dialog box that when displayed is centered

    GUISetBkColor(0x00E0FFFF)
    GUISetFont(9, 300)

    $tab = GUICtrlCreateTab(10, 10, 200, 100)

    $tab0 = GUICtrlCreateTabItem("tab0")
    GUICtrlCreateLabel("label0", 30, 80, 50, 20)
    $tab0OK = GUICtrlCreateButton("OK0", 20, 50, 50, 20)
    $tab0input = GUICtrlCreateInput("default", 80, 50, 70, 20)

    $tab1 = GUICtrlCreateTabItem("tab----1")
    GUICtrlCreateLabel("label1", 30, 80, 50, 20)
    $tab1combo = GUICtrlCreateCombo("", 20, 50, 60, 120)
    GUICtrlSetData(-1, "Trids|CyberSlug|Larry|Jon|Tylo", "Jon"); default Jon
    $tab1OK = GUICtrlCreateButton("OK1", 80, 50, 50, 20)

    $tab2 = GUICtrlCreateTabItem("tab2")
    GUICtrlSetState(-1, $GUI_SHOW); will be display first
    GUICtrlCreateLabel("label2", 30, 80, 50, 20)
    $tab2OK = GUICtrlCreateButton("OK2", 140, 50, 50)

    GUICtrlCreateTabItem(""); end tabitem definition

    GUICtrlCreateLabel("Click on tab and see the title", 20, 130, 250, 20)

    GUISetState()

    ; Run the GUI until the dialog is closed
    While 1
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
        If $msg = $tab Then
            ; display the clicked tab
            WinSetTitle("My GUI Tab", "", "My GUI Tab" & GUICtrlRead($tab))
        EndIf
    WEnd
EndFunc   ;==>Example