函数参考

_GUICtrlListView_SetBkColor

Sets the background color of the control

#Include <GuiListView.au3>
_GUICtrlListView_SetBkColor($hWnd, $iColor)

 

参数

$hWnd Handle to the control
$iColor Background color to set or CLR_NONE value for no background color

 

返回值

Success: True
Failure: False

 

注意/说明

None.

 

相关

_GUICtrlListView_GetBkColor

 

示例/演示


#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
#include <Constants.au3>

Opt('MustDeclareVars', 1)

$Debug_LV = False ; Check ClassName being passed to ListView functions, set to True and use a handle to another control to see it work

_Main()

Func _Main()
    Local $hListView
   
    GUICreate("ListView Set BkColor", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; Set colors
    _GUICtrlListView_SetBkColor($hListView, $CLR_MONEYGREEN)
    _GUICtrlListView_SetTextColor($hListView, $CLR_BLACK)
    _GUICtrlListView_SetTextBkColor($hListView, $CLR_MONEYGREEN)

    ; Add columns
    _GUICtrlListView_AddColumn($hListView, "Items", 100)

    ; Add items
    _GUICtrlListView_BeginUpdate($hListView)
    For $iI = 1 To 10
        _GUICtrlListView_AddItem($hListView, "Item " & $iI)
    Next
    _GUICtrlListView_EndUpdate($hListView)

    ; Show clors
    MsgBox(4160, "Information", "Back Color ....: " & _GUICtrlListView_GetBkColor($hListView) & @CRLF & _
            "Text Color ....: " & _GUICtrlListView_GetTextColor($hListView) & @CRLF & _
            "Text Back Color: " & _GUICtrlListView_GetTextBkColor($hListView))

    ; Loop until user exits
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main