函数参考

_GUICtrlListView_SetItemText

更改项目或子项文本

#Include <GuiListView.au3>
_GUICtrlListView_SetItemText($hWnd, $iIndex, $sText[, $iSubItem = 0])

参数

$hWnd 控件句柄
$iIndex 项目的 0 基索引
$sText 子项目文本
$iSubItem [可选参数] 子项的索引, 或 0, 仅设置项目.

返回值

成功: 返回 True
失败: 返回 False

注意/说明

 如果 $iSubItem = -1,则设置行

相关

_GUICtrlListView_GetItemText, _GUICtrlListView_GetItemTextArray, _GUICtrlListView_GetItemTextString, _GUICtrlListView_InsertItem

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; 检查传递给 ListView 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hListView

    GUICreate("ListView Set Item Text", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; 添加列
    _GUICtrlListView_AddColumn($hListView, "Items", 100)

    ; 添加项目
    _GUICtrlListView_AddItem($hListView, "Item 1")
    _GUICtrlListView_AddItem($hListView, "Item 2")
    _GUICtrlListView_AddItem($hListView, "Item 3")

    ; Set item 2 text
    _GUICtrlListView_SetItemText($hListView, 1, "New Item 2")
    MsgBox(4160, "信息", "Item 2 Text: " & _GUICtrlListView_GetItemText($hListView, 1))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main