函数参考


_GUIImageList_Create

创建 ImageList 控件

#Include <GuiImageList.au3>
_GUIImageList_Create([$iCX=16[, $iCY=16[, $iColor=4[, $iOptions=0[, $iInitial=4[, $iGrow=4]]]]]])

参数

$iCX [可选参数] 图像宽度像素值
$iCY [可选参数] 图像高度像素值
$icolor [可选参数] 图像色深度:
0 - 使用默认值
1 - 使用 4 位 DIB 区域 (设备无关点位图)
2 - 使用 8 位 DIB 区域 (设备无关点位图)
3 - 使用 16 位 DIB 区域 (设备无关点位图)
4 - 使用 24 位 DIB 区域 (设备无关点位图)
5 - 使用 32 位 DIB 区域 (设备无关点位图)
6 - 使用设备相关位图
$iOptions [可选参数] 选项标志.可以是以下值的组合:
1 - 使用蒙板
2 - 列表的图像镜像
4 - 图像列表包含图像带
$iInitial [可选参数] 图像列表最初包含的图像数量
$iGrow [可选参数] 当系统需要新图像空间时,图像列表可以增加的图像数.
这个参数代表调整图像列表大小时可以包含的图像数

返回值

成功: 返回控件句柄
失败: 返回 0

注意/说明

None.

相关

_GUIImageList_Destroy

示例/演示


#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>
#include <WindowsConstants.au3>

_Main()

Func _Main()
    Local $listview, $hImage
    Local $exStyles = BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES)

    GUICreate("ImageList Create", 400, 300)
    $listview = GUICtrlCreateListView("", 2, 2, 394, 268, BitOR($LVS_SHOWSELALWAYS, $LVS_NOSORTHEADER, $LVS_REPORT))
    _GUICtrlListView_SetExtendedListViewStyle($listview, $exStyles)
    GUISetState()

    ; 加载图像
    $hImage = _GUIImageList_Create(11, 11)
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap(GUICtrlGetHandle($listview), 0xFF0000, 11, 11))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap(GUICtrlGetHandle($listview), 0x00FF00, 11, 11))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap(GUICtrlGetHandle($listview), 0x0000FF, 11, 11))
    _GUICtrlListView_SetImageList($listview, $hImage, 1)

    ; 添加列
    _GUICtrlListView_AddColumn($listview, "Items", 120)

    ; 添加项目
    _GUICtrlListView_AddItem($listview, "Item 1", 0)
    _GUICtrlListView_AddItem($listview, "Item 2", 1)
    _GUICtrlListView_AddItem($listview, "Item 3", 2)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main