函数参考

_ArrayDisplay

在一个列表视图(listview)中显示指定的一维或二维数组.

#include <Array.au3>
_ArrayDisplay(Const ByRef $avArray [, $sTitle = "Array: ListView Display" [, $iItemLimit = -1 [, $iTranspose = 0 [, $sSeparator = "" [, $sReplace = "|" [, $sHeader = ""]]]]]])

参数

$avArray 要显示的数组
$sTitle [可选参数] 窗口显示的标题
$iItemLimit [可选参数] 要显示的列表视图的最大的项目(行)数
$iTranspose [可选参数] 如果不为 default , 将会像二维矩形那样将行列(长宽)互换
$sSeparator [可选参数] 快速设置 Opt("GUIDataSeparatorChar")
$sReplace [可选参数] 替换每个数组元素中的 $sSeparator 字符串
$sheader [可选参数] 列头名称(列头由"|"进行分割)

返回值

成功: 返回 1
失败: 返回 0, 并设置 @error:
@error: 1 - $avArray 不是一个数组
2 - $avArray 有太多的维度 (只能支持到二维数组)

注意/说明

The maximum number of items that can be displayed using _ArrayDisplay is 65530.
This due to the limitation with the number of controls that can be displayed in a GUI box.

相关

示例/演示


#include <Array.au3>

;===============================================================================
; 例子 1
;===============================================================================
Local $asControls = StringSplit(WinGetClassList("[active]", ""), @LF)
_ArrayDisplay($asControls, "活动窗口包含的'类'列表")

;===============================================================================
; 例子 2 (使用一个手动定义的数组)
;===============================================================================
Local $avArray[10]

$avArray[0] = "JPM"
$avArray[1] = "Holger"
$avArray[2] = "Jon"
$avArray[3] = "Larry"
$avArray[4] = "Jeremy"
$avArray[5] = "Valik"
$avArray[6] = "Cyberslug"
$avArray[7] = "Nutster"
$avArray[8] = "JdeB"
$avArray[9] = "Tylo"

_ArrayDisplay($avArray, "$avArray 为一维数组")
_ArrayDisplay($avArray, "$avArray 为颠倒的一维数组", -1, 1)

;===============================================================================
; 例子 3 (使用一个 StringSplit() 函数返回的数组)
;===============================================================================
$avArray = StringSplit(WinGetClassList("", ""), @LF)
_ArrayDisplay($avArray, "$avArray 为一个活动窗口包含的'类'列表")

;===============================================================================
; 示例 4 (一个二维数组)
;===============================================================================
Local $avArray[2][5] = [["JPM", "Holger", "Jon", "Larry", "Jeremy"],["Valik", "Cyberslug", "Nutster", "JdeB", "Tylo"]]
_ArrayDisplay($avArray, "$avArray 为二维数组")
_ArrayDisplay($avArray, "$avArray 为二维数组, 颠倒的", -1, 1)