函数参考

_ClipBoard_RegisterFormat

注册一个新的剪切板格式

#Include <Clipboard.au3>
_ClipBoard_RegisterFormat($sFormat)

参数

$sFormat 新剪切板格式名称

返回值

成功: 返回剪切板格式
失败: 返回 0

注意/说明

如果指定格式已存在, 新格式不会被注册并且返回已存在的格式.
多个应用程序在同一个注册的剪贴板格式中复制粘贴数据.
请注意,格式名称比较不区分大小写.

相关

_ClipBoard_EnumFormats

详情参考

在MSDN中搜索


示例/演示


#include <GUIConstantsEx.au3>
#include <Clipboard.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $iFormat

    ; 创建 GUI
    GUICreate("Clipboard", 600, 400)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 注册一个新的剪贴板格式
    $iFormat = _ClipBoard_RegisterFormat("AutoIt Library Text")
    If $iFormat <> 0 Then

        ; 显示新格式
        MemoWrite(_ClipBoard_GetFormatName($iFormat))
    Else
        _WinAPI_ShowError("_ClipBoard_RegisterFormat failed")
    EndIf

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; 写入消息到 memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite