函数参考

_Date_Time_GetTimeZoneInformation

返回当前时区设置

#Include <Date.au3>
_Date_Time_GetTimeZoneInformation()

参数

None.

返回值

返回如下格式数组:
    [0] - 夏时制. 可为下列之一:
    -1 - 失败
    0 - 当前时区不使用夏时制
    1 - 以标准时间操作夏时制时间
    2 - 以夏时制操作夏时制时间
    [1] - 在此计算机上本地时间的当前误差. 误差指相应的通用时间(UTC)和本地时间之间"分"的不同. 所有通用时间和本地时间使用的互译公式: UTC = local time + bias
    [2] - 标准时间描述
    [3] - 包含日期和将夏时制翻译为标准时间时的本地时间的$tagSYSTEMTIME结构.
    [4] - 用于发生在标准时间期间的本地时间翻译的偏差值. 该值加上偏差值以格式化用于标准时间期间的偏差. 多数时区中, 该值为0.
    [5] - 夏时制时间描述
    [6] - 包含日期和将标准时切换到夏时制时的本地时间的$tagSYSTEMTIME结构.
    [7] - 用于发生在夏时制期间的本地时间翻译的偏差值. 该值加上偏差值以格式化用于夏时制期间的偏差. 多数时区中, 该值为0.

注意/说明

 在 $tagSYSTEMTIME 结构中：

 wHour 与 wMinute 项代表时间

 wMonth 项代表月份

 wDayOfWeek 项代表星期(周),

 wDay 项代表一月内第几个星期 (取值 1 到 5, 其中 5 表示最后出现的星期).
 举例如下：
 指定 4 月第一个星期日 02:00 的表示法如下:

 wHour = 2, wMonth = 4, wDayOfWeek = 0, wDay = 1.
 指定 10 月最后一个星期四 02:00 的表示法如下:

 wHour = 2, wMonth = 10, wDayOfWeek = 4, wDay = 5.

相关

_Date_Time_SetTimeZoneInformation, $tagSYSTEMTIME

示例/演示


#include <GUIConstantsEx.au3>
#include <Date.au3>
#include <WindowsConstants.au3>

; 由于系统安全性,在 Vista 中 Windows API "SetTimeZoneInformation" 可能被拒绝

Global $iMemo

_Main()

Func _Main()
    Local $aOld, $aNew

    ; 创建 GUI
    GUICreate("Time", 400, 300)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 显示当前的时区信息
    $aOld = _Date_Time_GetTimeZoneInformation()
    ShowTimeZoneInformation($aOld, "Current")

    ; 设置新的时区信息
    If Not _Date_Time_SetTimeZoneInformation($aOld[1], "A3L CST", $aOld[3], $aOld[4], "A3L CDT", $aOld[6], $aOld[7]) Then
        MsgBox(4096, "错误", "System timezone cannot be SET" & @CRLF & @CRLF & _WinAPI_GetLastErrorMessage())
        Exit
    EndIf

    ; 显示新的时区信息
    $aNew = _Date_Time_GetTimeZoneInformation()
    ShowTimeZoneInformation($aNew, "New")

    ; 重设为原来的时区信息
    _Date_Time_SetTimeZoneInformation($aOld[1], $aOld[2], $aOld[3], $aOld[4], $aOld[5], $aOld[6], $aOld[7])

    ; 显示当前的时区信息
    $aOld = _Date_Time_GetTimeZoneInformation()
    ShowTimeZoneInformation($aOld, "Reset")

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; 写入一行到 memo 控件
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite

; 显示时区信息
Func ShowTimeZoneInformation(ByRef $aInfo, $comment)
    MemoWrite("******************* " & $comment & " *******************")
    MemoWrite("Result ............: " & $aInfo[0])
    MemoWrite("Current bias ......: " & $aInfo[1])
    MemoWrite("Standard name .....: " & $aInfo[2])
    MemoWrite("Standard date/time : " & _Date_Time_SystemTimeToDateTimeStr($aInfo[3]))
    MemoWrite("Standard bias......: " & $aInfo[4])
    MemoWrite("Daylight name .....: " & $aInfo[5])
    MemoWrite("Daylight date/time : " & _Date_Time_SystemTimeToDateTimeStr($aInfo[6]))
    MemoWrite("Daylight bias......: " & $aInfo[7])
EndFunc   ;==>ShowTimeZoneInformation