函数参考

_FTP_FindFileFirst

查找 FTP 服务器上第一个文件.

#Include <FTPEx.au3>
_FTP_FindFileFirst($l_FTPSession, $s_RemotePath, ByRef $h_Handle [, $l_Flags = 0 [, $l_Context = 0]])

参数

$l_FTPSession 由 _FTP_Connect() 返回.
$s_RemotePath 用于搜索文件的路径.
$h_Handle 返回给 _FTP_FindFileNext() 或者 _FTP_FindFileClose() 使用的句柄.
$l_Flags [可选参数] 参考备注.
$l_Context [可选参数] 一个变量, 它包含应用程序定义的值, 关联应用程序数据的搜索.
用于应用程序已调用 _FTP_SetStatusCallback() 时,设置一个状态回调函数.

返回值

成功: 返回一个数组, 参考备注.
失败: 返回 0 并设置 @ERROR

注意/说明

如果成功则返回一个数组:
[0] - 元素数量
[1] - 文件属性
[2] - 创建时间低位
[3] - 创建时间高位
[4] - 访问时间低位
[5] - 访问时间高位
[6] - 最后写入时间低位
[7] - 最后写入时间高位
[8] - 文件大小高位
[9] - 文件大小低位
[10] - 文件名
[11] - 别名

$l_Flags 可以是一个组合: $INTERNET_FLAG_HYPERLINK, $INTERNET_FLAG_NEED_FILE, $INTERNET_FLAG_NO_CACHE_WRITE, $INTERNET_FLAG_RELOAD, $INTERNET_FLAG_RESYNCHRONIZE

相关

_FTP_FindFileNext, _FTP_FindFileClose, _FTP_SetStatusCallback

详情参考

在MSDN中搜索


示例/演示


#include <FTPEx.au3>

Local $server = 'ftp.csx.cam.ac.uk'
Local $username = ''
Local $pass = ''

Local $Open = _FTP_Open('MyFTP Control')
Local $Conn = _FTP_Connect($Open, $server, $username, $pass)

Local $h_Handle
Local $aFile = _FTP_FindFileFirst($Conn, "/pub/software/programming/pcre/", $h_Handle)
ConsoleWrite('$Filename = ' & $aFile[10] & ' attribute = ' & $aFile[1] & '  -> Error code: ' & @error & @CRLF)

Local $FindClose = _FTP_FindFileClose($h_Handle)

Local $Ftpc = _FTP_Close($Open)