函数参考

_GDIPlus_ArrowCapGetFillState

获取箭头帽填充状态

#Include <GDIPlus.au3>
_GDIPlus_ArrowCapGetFillState($hArrowCap)

参数

$hArrowCap 箭头帽对象句柄

返回值

True: 以填充状态
False: 非填充状态或错误，并设置 @error

注意/说明

None.

相关

_GDIPlus_ArrowCapSetFillState

详情参考

在MSDN中搜索


示例/演示


#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>

_Main()

Func _Main()
    Local $hGUI, $hGraphic, $hPen, $hEndCap

    ; 创建 GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState()

    ; 创建资源
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    $hPen = _GDIPlus_PenCreate(0xFF000000, 4)
    $hEndCap = _GDIPlus_ArrowCapCreate(4, 6)

    ; 显示填充状态
    MsgBox(4096, "信息", "Fill state: " & _GDIPlus_ArrowCapGetFillState($hEndCap))

    ; 描绘箭头 1
    _GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 130, 390, 130, $hPen)

    ; 描绘箭头 2
    _GDIPlus_ArrowCapSetFillState($hEndCap, False)
    _GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 160, 390, 160, $hPen)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; 清理资源
    _GDIPlus_ArrowCapDispose($hEndCap)
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>_Main