函数参考


_GDIPlus_GraphicsDrawString

绘制字符串

#Include <GDIPlus.au3>
_GDIPlus_GraphicsDrawString($hGraphics, $sString, $nX, $nY[, $sFont = "Arial"[, $fSize = 10[, $iFormat = 0]]])

参数

$hGraphics 图形对象的句柄
$sString 将绘制的字符串
$nX 绘制字符串的 X 坐标
$nY 绘制字符串的 Y 坐标
$sFont [可选参数] 使用的字体名称
$fSize [可选参数] 使用的字体大小
$iFormat [可选参数]格式标志.可以是下列一或多个:
0x0001 - 阅读顺序从右到左
0x0002 - 文本行垂直绘制
0x0004 - 允许字符串超出所属矩形
0x0020 - 控制字符的 Unicode 布局与典型显示
0x0400 - 指定备用字体,用来替代请求字体不支持的字符
0x0800 - 每行行尾包含的空白符,以字符为测量单位
0x1000 - 禁止该文本换行到下一行
0x2000 - 仅整行都在所属矩形内
0x4000 - 允许显示超出所属矩形的字符和文本

返回值

成功: 返回 True
失败: 返回 False

注意/说明

None.

相关

_GDIPlus_GraphicsDrawStringEx

示例/演示


#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>

_Main()

Func _Main()
    Local $hGUI, $hGraphic

    ; 创建 GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState()

    ; 描绘字符串
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    _GDIPlus_GraphicsDrawString($hGraphic, "Hello world", 140, 110)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; 清理资源
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()

EndFunc   ;==>_Main