函数参考


_GUICtrlComboBoxEx_GetEditSel

获取组合框的编辑控件里当前选项开始和结束字符的位置

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_GetEditSel($hWnd)

参数

$hWnd 控件句柄

返回值

成功: 返回如下格式的数组:
        [0] - 起始位置.
        [1] - 结束位置.失败 :返回 -1
失败: 返回 -1

注意/说明

 如果消息发送到具有 $CBS_DROPDOWN 或 $CBS_DROPDOWNLIST 样式的组合框, 该函数将失败.

相关

_GUICtrlComboBoxEx_SetEditSel

示例/演示


#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Debug_CB = False ;检查传递给 ComboBox/ComboBoxEx 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hImage, $aSel, $hCombo

    ; 创建 GUI
    $hGUI = GUICreate("ComboBoxEx Get Edit Sel", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 70, BitOR($CBS_SIMPLE, $WS_VSCROLL, $WS_BORDER))
    $iMemo = GUICtrlCreateEdit("", 2, 72, 396, 226, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

    ; 添加字符串
    For $x = 0 To 8
        _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)), $x, $x)
    Next

    ;Set Cur Sel
    _GUICtrlComboBoxEx_SetCurSel($hCombo, Random(0, 8, 1))

    ;Set Edit Sel
    _GUICtrlComboBoxEx_SetEditSel($hCombo, 0, 4)

    ;Get Edit Sel
    $aSel = _GUICtrlComboBoxEx_GetEditSel($hCombo)
    MemoWrite(StringFormat("Selected: [%d][%d]", $aSel[0], $aSel[1]))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; 写入一行到 memo 控件
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite