函数参考

_GUICtrlEdit_LineIndex

获取指定行的第一个字符的字符索引

#include <GuiEdit.au3>
_GUICtrlEdit_LineIndex($hWnd [, $iIndex = 0])

参数

$hWnd 控件的控件ID/句柄
$iIndex [可选参数] 指定行从 0 开始的行的数字

返回值

成功: 返回 $iIndex 参数指定行的字符索引
失败: 返回 -1,表明指定行大于编辑控件中的行数.

注意/说明

$iIndex = -1,则指定当前插入符号所在行

相关

示例/演示


#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Debug_Ed = False ; 检查传递给 Edit 函数的类名, 设置为真并使用另一控件的句柄可以看出它是否有效

_Main()

Func _Main()
    Local $hStatusBar, $hEdit, $hGUI
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"
    Local $aPartRightSide[2] = [378, -1], $iRandom

    ; 创建 GUI
    $hGUI = GUICreate("Edit Line Index", 400, 300)
    $hEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
    _GUICtrlStatusBar_SetIcon($hStatusBar, 1, 97, "shell32.dll")
    GUISetState()

    ; 设置边距
    _GUICtrlEdit_SetMargins($hEdit, BitOR($EC_LEFTMARGIN, $EC_RIGHTMARGIN), 10, 10)

    ; 设置文本
    _GUICtrlEdit_SetText($hEdit, FileRead($sFile))

    ; 行索引
    $iRandom = Random(0, _GUICtrlEdit_GetLineCount($hEdit) - 1, 1)
    _GUICtrlStatusBar_SetText($hStatusBar, "Char Index: " & _GUICtrlEdit_LineIndex($hEdit, $iRandom) & " from Line: " & $iRandom)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main