函数参考

_GUICtrlEdit_PosFromChar

获取指定字符在编辑框控件客户区中的坐标

#include <GuiEdit.au3>
_GUICtrlEdit_PosFromChar($hWnd, $iIndex)

参数

$hWnd 控件的控件ID/句柄
$iIndex 字符的 0 基索引

返回值

成功: 返回如下格式的数组:
    [0] - 水平坐标
    [1] - 垂直坐标

注意/说明

None.

相关

示例/演示


#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Debug_Ed = False ; 检查传递给 Edit 函数的类名, 设置为真并使用另一控件的句柄可以看出它是否有效

_Main()

Func _Main()
    Local $hStatusBar, $hEdit, $hGUI
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"
    Local $aPartRightSide[3] = [200, 378, -1], $aPos

    ; 创建 GUI
    $hGUI = GUICreate("Edit Pos From Char", 400, 300)
    $hEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
    _GUICtrlStatusBar_SetIcon($hStatusBar, 2, 97, "shell32.dll")
    GUISetState()

    ; 设置边距
    _GUICtrlEdit_SetMargins($hEdit, BitOR($EC_LEFTMARGIN, $EC_RIGHTMARGIN), 10, 10)

    ; 设置文本
    _GUICtrlEdit_SetText($hEdit, FileRead($sFile))

    ; 字符的位置
    $aPos = _GUICtrlEdit_PosFromChar($hEdit, 300)
    _GUICtrlStatusBar_SetText($hStatusBar, "Horizontal Coord: " & $aPos[0])
    _GUICtrlStatusBar_SetText($hStatusBar, "Vertical Coord: " & $aPos[1], 1)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main