函数参考

_GUICtrlListBox_SetCaretIndex

设置多选择列表框指定索引项目的焦点矩形

#include <GuiListBox.au3>
_GUICtrlListBox_SetCaretIndex($hWnd, $iIndex [, $fPartial = False])

参数

$hWnd 控件的控件ID/句柄
$iIndex 项目的 0 基索引
$fPartial [可选参数] 如果为 False,项目将滚动至完全可见;
如果 True, 项目滚动至部分可见.

返回值

成功: 返回 True
失败: 返回 False

注意/说明

None.

相关

_GUICtrlListBox_GetCaretIndex

示例/演示


#include <GuiListBox.au3>
#include <GUIConstantsEx.au3>

$Debug_LB = False ;检查传递给 ListBox 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $iIndex, $hListBox

    ; 创建 GUI
    GUICreate("List Box Set Caret Index", 400, 296)
    $hListBox = GUICtrlCreateList("", 2, 2, 396, 296)
    GUISetState()

    ; 添加字符串
    _GUICtrlListBox_BeginUpdate($hListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($hListBox, StringFormat("%03d : Random string", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_EndUpdate($hListBox)

    ; Set caret index
    _GUICtrlListBox_SetCaretIndex($hListBox, 2)

    ; Read caret index
    $iIndex = _GUICtrlListBox_GetCaretIndex($hListBox)
    _GUICtrlListBox_SetCurSel($hListBox, $iIndex)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main