函数参考

_GUICtrlListBox_SetSel

选择多选择列表框中的字符串

#include <GuiListBox.au3>
_GUICtrlListBox_SetSel($hWnd [, $iIndex = -1 [, $fSelect = -1]])

参数

$hWnd 控件的控件ID/句柄
$iIndex [可选参数] 项目的 0 基索引
$fSelect [可选参数] 指定如何设置选择.

返回值

成功: 返回 True
失败: 返回 False

注意/说明

 若指定 $iIndex 为 -1,将切换所有项目的选择/取消选择状态(忽略 $fSelect 参数)

相关

_GUICtrlListBox_GetSel

示例/演示


#include <GuiListBox.au3>
#include <GUIConstantsEx.au3>

$Debug_LB = False ;检查传递给 ListBox 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hListBox

    ; 创建 GUI
    GUICreate("List Box Set Sel", 400, 296)
    $hListBox = GUICtrlCreateList("", 2, 2, 396, 296, BitOR($LBS_STANDARD, $LBS_EXTENDEDSEL))
    GUISetState()

    ; 添加字符串
    _GUICtrlListBox_BeginUpdate($hListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($hListBox, StringFormat("%03d : Random string", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_EndUpdate($hListBox)

    ; Select a few items
    _GUICtrlListBox_SetSel($hListBox, 3)
    _GUICtrlListBox_SetSel($hListBox, 4)
    _GUICtrlListBox_SetSel($hListBox, 5)

    ; Show the item selection state
    MsgBox(4160, "信息", "Item 5 Selected: " & _GUICtrlListBox_GetSel($hListBox, 4))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main