函数参考

_GUICtrlListView_GetItemTextArray

添加所有列表视图控件项目的文本到一个数组

#Include <GuiListView.au3>
_GUICtrlListView_GetItemTextArray($hWnd[, $iItem = -1])

参数

$hWnd 控件句柄
$iItem [可选参数] 要获取的项目的基于0开始的项目索引

返回值

成功: 返回如下格式数组:
[0] - 控件中列数 (n)
[1] - 第一列的文本字符串(主项文本)
[2] - 第二列的文本字符串(主项第一子项文本)
[n] - 最后列的文本字符串(主项的末项文本)
失败: 返回如下格式数组:
[0] - 控件中列数 (0)

注意/说明

 如 $iItem = -1, 则获取当前选定项目的文本.

相关

_GUICtrlListView_SetItemText, _GUICtrlListView_GetItemText, _GUICtrlListView_GetItemTextString

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; 检查传递给 ListView 函数的类名, 设置为真并使用另一控件的句柄可以看出它是否有效

_Main()

Func _Main()
    Local $aItem, $sText, $hListView

    GUICreate("ListView Get Item Text Array", 400, 300)

    $hListView = GUICtrlCreateListView("col1|col2|col3", 2, 2, 394, 268)
    GUICtrlCreateListViewItem("line1|data1|more1", $hListView)
    GUICtrlCreateListViewItem("line2|data2|more2", $hListView)
    GUICtrlCreateListViewItem("line3|data3|more3", $hListView)
    GUICtrlCreateListViewItem("line4|data4|more4", $hListView)
    GUICtrlCreateListViewItem("line5|data5|more5", $hListView)

    GUISetState()

    ; 获取第二项的文本
    $aItem = _GUICtrlListView_GetItemTextArray($hListView, 1)
    For $i = 1 To $aItem[0]
        $sText &= StringFormat("Column[%2d] %s", $i, $aItem[$i]) & @LF
    Next

    MsgBox(4160, "信息", "Item 2 (All Columns) Text: " & @LF & @LF & $sText)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main