函数参考

_GUICtrlListView_SetColumnWidth

更改列宽

#Include <GuiListView.au3>
_GUICtrlListView_SetColumnWidth($hWnd, $iCol, $iWidth)

参数

$hWnd 控件句柄
$iCol 有效列的 0 基索引,对于列表视图模式,这个参数必须设置为零.
$iWidth 新的列像素宽度.
对于报表视图模式,支持以下特殊值:
$LVSCW_AUTOSIZE - 自动设置列尺寸.
$LVSCW_AUTOSIZE_USEHEADER - 自动设置列尺寸以适应标题文本.
如果在最后一列使用此此值,则此宽度将填充列表视图其余列的宽度.

返回值

成功: 返回 True
失败: 返回 False

注意/说明

None.

相关

_GUICtrlListView_GetColumnWidth, _GUICtrlListView_HideColumn

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; 检查传递给 ListView 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hListView

    GUICreate("ListView Set Column Width", 400, 300)
    $hListView = GUICtrlCreateListView("Column 1|Column 2|Column 3|Column 4", 2, 2, 394, 268)
    GUISetState()

    ; Change column 1 width
    MsgBox(4160, "信息", "Column 1 Width: " & _GUICtrlListView_GetColumnWidth($hListView, 0))
    _GUICtrlListView_SetColumnWidth($hListView, 0, 150)
    MsgBox(4160, "信息", "Column 1 Width: " & _GUICtrlListView_GetColumnWidth($hListView, 0))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>_Main