函数参考


_GUICtrlListView_SetOutlineColor

设置边框颜色

#Include <GuiListView.au3>
_GUICtrlListView_SetOutlineColor($hWnd, $iColor)

参数

$hWnd 控件句柄
$iColor 边框颜色

返回值

返回先前轮廓颜色

注意/说明

 最低操作系统 - Windows XP.
 控件必须有 $LVS_EX_BORDERSELECT 扩展样式.

相关

_GUICtrlListView_GetOutlineColor

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

$Debug_LV = False ; 检查传递给 ListView 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hImage, $hListView

    GUICreate("ListView Set Outline Color", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUICtrlSetStyle($hListView, $LVS_ICON)
    ; 启用扩展控件样式
    _GUICtrlListView_SetExtendedListViewStyle($hListView, $LVS_EX_BORDERSELECT)
    GUISetState()

    ; 加载图像
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($hListView, $hImage, 0)

    ; 添加列
    _GUICtrlListView_AddColumn($hListView, "Items", 100)

    ; 添加项目
    _GUICtrlListView_AddItem($hListView, "Item 1", 0)
    _GUICtrlListView_AddItem($hListView, "Item 2", 1)
    _GUICtrlListView_AddItem($hListView, "Item 3", 2)

    ; Set outline color
    _GUICtrlListView_SetOutlineColor($hListView, 0x0000FF)
    MsgBox(4160, "信息", "Outline Color: " & Hex(_GUICtrlListView_GetOutlineColor($hListView)))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main