函数参考

_GUICtrlMonthCal_GetColor

检索控件的特定颜色

#Include <GuiMonthCal.au3>
_GUICtrlMonthCal_GetColor($hWnd, $iIndex)

参数

$hWnd 控件句柄
$iIndex 检索颜色的控件部位:
$MCSC_BACKGROUND - 月份之间的背景颜色
$MCSC_TEXT - 月内文本的颜色
$MCSC_TITLEBK - 日历标题的背景颜色
$MCSC_TITLETEXT - 日历标题的文字颜色
$MCSC_MONTHBK - 本月的背景颜色
$MCSC_TRAILINGTEXT - 上一天和下一天的文本颜色

返回值

成功: 返回显示的颜色
失败: 返回 -1

注意/说明

None.

相关

_GUICtrlMonthCal_SetColor

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiMonthCal.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>

$Debug_MC = False ; Check ClassName being passed to MonthCal functions, set to True and use a handle to another control to see it work

Global $iMemo

_Main()

Func _Main()
    Local $hMonthCal

    ; 创建 GUI
    GUICreate("Month Calendar Get Color", 400, 300)
    $hMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, $WS_BORDER, 0x00000000)

    ; 创建 memo 控件
    $iMemo = GUICtrlCreateEdit("", 4, 168, 392, 128, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; Get/Set calendar color
    MemoWrite("Background: 0x" & Hex(_GUICtrlMonthCal_GetColor($hMonthCal, $MCSC_MONTHBK), 6))
    _GUICtrlMonthCal_SetColor($hMonthCal, $MCSC_MONTHBK, $CLR_MONEYGREEN)
    MemoWrite("Background: 0x" & Hex(_GUICtrlMonthCal_GetColor($hMonthCal, $MCSC_MONTHBK), 6))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; 写入消息到 memo
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite