函数参考


_GUICtrlRebar_AddBand

添加带区控件

#Include <GuiRebar.au3>
_GUICtrlRebar_AddBand($hwndRebar, $hwndChild[, $iMinWidth = 100[, $iDefaultWidth = 100[, $sText = ""[, $iIndex = -1[, $fStyle = -1]]]]])

参数

$hwndRebar 伸缩条控件句柄
$hwndChild 添加带区的控件句柄
$iMinWidth [可选参数] 带区最小宽度
$iDefaultWidth [可选参数] 带区像素长度
$sText [可选参数] 带区文本
$iIndex [可选参数] 带区插入的 0 索引位置
如果此参数设置为 -1,带区将添加到最后位置
$fStyle [可选参数] 带区样式标志.此值可以是以下组合:
$RBBS_BREAK - 带区在新行.
$RBBS_CHILDEDGE - 带区是一个有顶部和底部边缘的子窗口.
$RBBS_FIXEDBMP - 带区调整大小时,不移动背景位图.
$RBBS_FIXEDSIZE - 带区不能调整大小. 在此样式中, 带区不显示控制尺寸
$RBBS_GRIPPERALWAYS - 版本 4.71. 带区具有尺寸控制, 即使伸缩条上仅有一个带区.
$RBBS_HIDDEN - 带区不可见.
$RBBS_NOGRIPPER - 版本 4.71. 带区没有尺寸控制, 即使伸缩条上有多个带区.
$RBBS_USECHEVRON - 版本 5.80. 当带区小于 cxIdeal 时显示一个 (∧) 上尖号或下尖号 (∨).
$RBBS_VARIABLEHEIGHT - 版本 4.71. 带区可由伸缩条改变大小;cyIntegral 与 cyMaxChild 将影响伸缩条如何调整带区.
$RBBS_NOVERT - 垂直时不显示.
$RBBS_USECHEVRON - 显示下拉按钮.
$RBBS_HIDETITLE - 阻止带区标题隐藏.
$RBBS_TOPALIGN - 带区置于顶行.

返回值

成功: 返回 True
失败: 返回 False

注意/说明

None.

相关

_GUICtrlRebar_AddToolBarBand, _GUICtrlRebar_DeleteBand

示例/演示


#include <GuiReBar.au3>
#include <GuiComboBox.au3>
#include <GuiDateTimePicker.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
#include <GUIConstantsEx.au3>

$Debug_RB = False

_Main()

Func _Main()
    Local $hgui, $btnExit, $hCombo, $hReBar, $hDTP, $hInput

    $hgui = GUICreate("Rebar", 400, 396, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_MAXIMIZEBOX))

    ; 创建伸缩条控件
    $hReBar = _GUICtrlRebar_Create($hgui, BitOR($CCS_TOP, $WS_BORDER, $RBS_VARHEIGHT, $RBS_AUTOSIZE, $RBS_BANDBORDERS))

    ; 在伸缩条中创建一个组合框
    $hCombo = _GUICtrlComboBox_Create($hgui, "", 0, 0, 120)

    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; 在伸缩条中创建一个日期和时间选取器
    $hDTP = _GUICtrlDTP_Create($hgui, 0, 0, 190)

    ; 在伸缩条中创建一个输入框
    $hInput = GUICtrlCreateInput("Input control", 0, 0, 120, 20)

    ; 添加含控件的纽带
    _GUICtrlRebar_AddBand($hReBar, $hCombo, 120, 200, "Dir *.exe")

    ; 添加并设置焦点到第二行
    _GUICtrlRebar_AddBand($hReBar, $hDTP, 120)
    _GUICtrlRebar_SetBandStyleBreak($hReBar, 1)

    ; 添加到伸缩条的开始处
    _GUICtrlRebar_AddBand($hReBar, GUICtrlGetHandle($hInput), 120, 200, "Name:", 0)

    $btnExit = GUICtrlCreateButton("Exit", 150, 360, 100, 25)
    GUISetState(@SW_SHOW)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $btnExit
                Exit
        EndSwitch
    WEnd
EndFunc   ;==>_Main