函数参考


_GUICtrlRichEdit_Create

创建编辑控件

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_Create($hWnd, $sText, $iLeft, $iTop [, $iWidth = 150 [, $iHeight = 150 [, $iStyle = -1 [, $iExStyle = -1]]]])

参数

$hWnd 父窗口或所有者窗口的句柄
$sText 控件将显示的文本
$iLeft 控件水平位置
$iTop 控件垂直位置
$iWidth [可选参数] 控件宽度
$iHeight [可选参数] 控件高度
$iStyle [可选参数] 控件样式:
$ES_AUTOHSCROLL - 当用户在行尾键入字符,文本自动滚动右侧10个字符.
$ES_AUTOVSCROLL - 用户在最后一行按下 Enter 键,文本自动滚动 1 页.
$WS_HSCROLL - 控件具有水平滚动条
$WS_VSCROLL - 控件具有垂直滚动条
$ES_CENTER - 控件内文本居中.
$ES_LEFT - 文本左对齐.
$ES_MULTILINE - 生成多行控件(默认)
$ES_NOHIDESEL - 选中的文本反白显示,即使控件没有焦点也如此.
$ES_NUMBER - 只允许输入数字.
$ES_READONLY - 阻止用户输入或编辑文本.
$ES_RIGHT - 文本右对齐.
$ES_WANTRETURN - 当用户按下 Enter 键时,插入一个回车(默认)
$ES_PASSWORD - 键入字符显示为星号(*)
默认: 0
强制: WS_CHILD, $WS_VISIBLE, $WS_TABSTOP unless $ES_READONLY
$iExStyle [可选参数] 控件扩展样式,适用标准的 $WS_EX_ 常量.

返回值

成功: 返回 RichEdit 控件句柄
失败: 返回 0 并设置@error
@error: 103 - $iLeft 不是正数或零
104 - $iTop 不是正数或零
105 - $iWidth 不是正数或 -1
106 - $iHeight 不是正数或 -1
107 - $iStyle 不是正数或零也不是 -1
108 - $iExStyle 不是正数或零也不是 -1

注意/说明

None.

相关

_GUICtrlRichEdit_Destroy

示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Main()

Func Main()
    Local $hGui, $hRichEdit, $iMsg
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "This is more text")
    GUISetState()

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
        EndSelect
    WEnd
EndFunc   ;==>Main