函数参考


_GUICtrlRichEdit_GetCharColor

检索所选文本的颜色,如果没有选定文本,则检索插入点右边的字符

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetCharColor($hWnd)

参数

$hWnd 控件句柄

返回值

成功: 如果选定文本的颜色是一致的,则返回 COLORREF 值的 @extended 设置为 1
失败: 设置@error:
@error: 101 - $hWnd 参数值不是句柄

注意/说明

If you need to create an color array use _ColorGetCOLORREF() not _ColorGetRGB().

相关

_GUICtrlRichEdit_SetCharColor

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Color.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    _GUICtrlRichEdit_SetText($hRichEdit, "Paragraph 1")
    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        Report("1. Initial setting")
                    Case 2
                        _GUICtrlRichEdit_SetCharColor($hRichEdit, "304050")
                        Report("2. Setting is now")
                    Case 3
                        _GUICtrlRichEdit_SetSel($hRichEdit, 1, 5)
                        _GUICtrlRichEdit_SetCharColor($hRichEdit, "sys")
                        Report("3. Background of a few characters changed")
                    Case 4
                        _GUICtrlRichEdit_Deselect($hRichEdit)
                        ; 把所有的文本流保存到桌面,这样您可以在 Word 中查看设置.
                        _GUICtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
                        Report("4. Written to file")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    Local $iColor = _GUICtrlRichEdit_GetCharColor($hRichEdit)
    Local $aRet = _ColorGetRGB($iColor)
    $sMsg = $sMsg & @CR & @CR & $aRet[0] & ";" & $aRet[1] & ";" & $aRet[2] & " Color=0x" & Hex($iColor)
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report