获取第一选中段落;或没有选择时的当前段落的边框设置
#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetParaBorder($hWnd)
| $hWnd | 控件句柄 |
| 成功: | 设置第一选定段落 - 返回由分号 (:) 分隔的字符串值 : | |
| 值 1 | ||
| 一个或多个: | ||
| l - 左侧边框 | ||
| r - 右侧边框 | ||
| t - 顶端边框 | ||
| b - 底部边框 | ||
| i - 内侧边框 | ||
| o - 外侧边框 | ||
| 或空 - 没有边框 | ||
| 值 2 - 线条样式 - one of: | ||
| none - 没有线条 | ||
| .75 - 3/4 磅 | ||
| 1.5 - 1 1/2 磅 | ||
| 2.25 - 2 1/4 磅 | ||
| 3 - 3 磅s | ||
| 4.5 - 4 1/2 磅 | ||
| 6 - 6 磅s | ||
| .75d - 1/2 磅, 双精度型 | ||
| 1.5d - 1 1/2 磅, 双精度型 | ||
| 2.25d - 2 1/4 磅, 双精度型 | ||
| .75g - 3/4 point grey | ||
| .75gd - 3/4 point 灰色虚线 | ||
| 值 3 - one of: | ||
| aut - 自动颜色 | ||
| blk - 黑色 | ||
| blu - 蓝色 | ||
| cyn - 青色 | ||
| grn - 绿色 | ||
| mag - 紫色 | ||
| red - 红色 | ||
| yel - 黄色 | ||
| whi - 白色 | ||
| dbl - 深蓝 | ||
| dgn - 深绿色 | ||
| dmg - 深紫红色 | ||
| drd - 暗红 | ||
| dyl - 暗黄 | ||
| dgy - 暗灰 | ||
| lgy - 浅灰 | ||
| 值 4 - 边框与文本的间距(空间单位) | ||
| 值 5 - 范围: | ||
| a - 所有(或使用的)选定段落使用这些设置 | ||
| f - 第一选定使用这些设置,但其它则不使用 | ||
| c - 当前段落使用这些设置 | ||
| 失败: | 返回 "" ,设置@error: | |
| @error: | 101 - $hWnd 参数值不是句柄 |
在MSDN中搜索
#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $lblMsg, $hRichEdit
Main()
Func Main()
Local $hGui, $iMsg, $iStep = 0, $btnNext
$hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
$btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
GUISetState()
_GUICtrlRichEdit_AppendText($hRichEdit, "First paragraph")
Report("0. First paragraph: default settings")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~ GUIDelete() ; 同样行
Exit
Case $iMsg = $btnNext
$iStep += 1
Switch $iStep
Case 1
_GUICtrlRichEdit_AppendText($hRichEdit, @CR & "Second paragraph")
_GUICtrlRichEdit_SetParaBorder($hRichEdit, "o", 3, "mag", 0.25)
Report("1. Second paragraph: with border (should show in Word)")
Case 2
_GUICtrlRichEdit_SetSel($hRichEdit, 10, -1)
Report("2. Settings of first paragraph in selection")
Case 3
_GUICtrlRichEdit_SetParaBorder($hRichEdit, "l", 6, "blu")
Report("3. Settings of both paragraphs changed")
Case 4
_GUICtrlRichEdit_SetParaBorder($hRichEdit, Default, ".75gd")
Report("4. Line style changed")
Case 5
; 把所有的文本流保存到桌面,这样您可以在 Word 中查看边框设置.
_GUICtrlRichEdit_Deselect($hRichEdit)
_GUICtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
GUICtrlSetState($btnNext, $GUI_DISABLE)
EndSwitch
EndSelect
WEnd
EndFunc ;==>Main
Func Report($sMsg)
$sMsg = $sMsg & @CR & @CR & "Get function returns " & @CR & _GUICtrlRichEdit_GetParaBorder($hRichEdit)
GUICtrlSetData($lblMsg, $sMsg)
ControlFocus($hRichEdit, "", "")
EndFunc ;==>Report