函数参考


_GUICtrlRichEdit_GetSel

获取选中字符区间的低、高位置

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetSel($hWnd)

参数

$hWnd 控件句柄

返回值

成功: 返回这个格式的数组:[, ]
失败: 设置@error
@error: 101 - $hWnd 参数值不是句柄

注意/说明

 文本第一个字符的字符区间位置为 0.
 如果高、低位相等, 则没有选中的文本.

相关

_GUICtrlRichEdit_SetSel, _GUICtrlRichEdit_GetSelText, _GUICtrlRichEdit_GetSelAA, _GUICtrlRichEdit_GetTextInLine, _GUICtrlRichEdit_Deselect, _GUICtrlRichEdit_IsTextSelected

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    _GUICtrlRichEdit_SetSel($hRichEdit, 2, 10)

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        Report("1. Text is selected from inter-character position")
                    Case 2
                        _GUICtrlRichEdit_Deselect($hRichEdit)
                        Report("2. No text is selected now")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    Local $aPos = _GUICtrlRichEdit_GetSel($hRichEdit)
    $sMsg = $sMsg & @CR & @CR & "Get function returns " & $aPos[0] & "," & $aPos[1]
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report