函数参考

_GUICtrlRichEdit_GetTextLength

获取控件中的整个文本的长度

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetTextLength($hWnd [, $fExact = True [, $fChars = False]])

参数

$hWnd Handle to control
$fExact [可选参数] True Return the exact length
       - = False return at least the number of characters in the control (faster)
Default: exact length
$fChars [可选参数] True - return length in characters
          = False - return length in bytes
Default: bytes

返回值

成功: 返回字符长度,或字节长度
失败: 返回 0,设置@error
@error: 101 - $hWnd 参数值不是句柄
102 - $fExact 必须是 True 或 False
103 - $fChars 必须是 True 或 False

注意/说明

None.

相关

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    GUISetState()

    _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "This is appended text.")

    Report("There are " & _GUICtrlRichEdit_GetTextLength($hRichEdit, True, True) & _
            " characters in the control")

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    GUICtrlSetData($lblMsg, $sMsg)
EndFunc   ;==>Report