函数参考


_GUICtrlRichEdit_IsModified

检索 RichEdit 控件的修改标志状态

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_IsModified($hWnd)

参数

$hWnd 控件句柄

返回值

成功: 返回 True 或 False
失败: 设置@error
@error: 101 - $hWnd 参数值不是句柄

注意/说明

 控件创建时,系统自动设置修改标志为 False.
 如果文本被用户或编程修改时,系统设置修改标志为 True
 调用 _GUICtrlRichEdit_SetModified 设置或清除该标志

相关

_GUICtrlRichEdit_SetModified, _GUICtrlRichEdit_GetText

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    Report("Initial state after creation")

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "A paragraph")
                        Report("Added some text")
                    Case 2
                        _GUICtrlRichEdit_SetModified($hRichEdit, False)
                        Report("After clearing the modification flag")
                    Case 3
                        GUICtrlSetData($lblMsg, "Type some text. Then click on Next")
                        ControlFocus($hRichEdit, "", "")
                    Case 4
                        Report("After typing")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    $sMsg = $sMsg & @CR & @CR & "State is " & _GUICtrlRichEdit_IsModified($hRichEdit)
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report