函数参考


_GUICtrlRichEdit_ScrollLines

滚动多行文本

#Include <GuiRichEdit.au3>
_GUICtrlRichEdit_ScrollLines($hWnd, $iQlines)

参数

$hWnd 控件句柄
$iQlines 滚动的行数

返回值

成功: 返回 True
失败: 返回 False设置@error
@error: 101 - $hWnd 参数值不是句柄
102 - $iQlines 不是数字
700 - 试图滚动一个只有行控件

注意/说明

 向下滚动,设置 $iQlines为正值; 向上滚动,则设置为负值.
 _GUICtrlRichEdit_ScrollLines 是规范的:
 如果 $iQlines 大于当前行行数,它滚动到显示的最后一行.
 如果 $iQlines 为负值,并指定为第一个行的前面行,
 它滚动到控件窗口显示在上方的第一行.

相关

_GUICtrlRichEdit_ScrollLineOrPage, _GUICtrlRichEdit_ScrollToCaret

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    For $i = 1 To 20
        _GUICtrlRichEdit_AppendText($hRichEdit, "Line " & $i & @CR)
    Next
    _GUICtrlRichEdit_AppendText($hRichEdit, "Line 21")

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_ScrollLines($hRichEdit, -10.2)
                        Report("Scrolled up")
                    Case 2
                        _GUICtrlRichEdit_ScrollLines($hRichEdit, +100)
                        Report("Scrolled down so only last line shows")
                    Case 3
                        _GUICtrlRichEdit_ScrollLines($hRichEdit, -200)
                        Report("Scrolled up all the way")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report