函数参考

_GUICtrlRichEdit_SetParaIndents

设置(第一)当前选择(或没有选择时的插入点所在段落)的缩进

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetParaIndents($hWnd [, $vLeft = Default [, $iRight = Default [, $iFirstLine = Default]]])

参数

$hWnd 控件句柄
$vLeft [可选参数] 段落的左边缩进 (空间单位)
 绝对值 - 数字
 相对于以前位置 - 字符串 - "+<数字>" 或 "-<数字>"
$iRight [可选参数] 段落的右侧缩进 (空间单位)
$iFirstLine [可选参数] 第一行的缩进相对于其它行(空间单位)

返回值

成功: 返回 True
失败: 返回 False,并设置@error
@error: 101 - $hWnd 参数值不是句柄
103 - $iRight 不是一个数字
104 - $iFirstLine 不是一个数字
1021 - $vLeft 既不是一个数字,也不是一个数字组成的字符串
1022 - $vLeft 开始段落的主要部分在客户区左侧
200 - 第一行凸出超出客户区
700 - 操作失败

注意/说明

$iLeft 的整数值, $iRight 与 $iFirstLine 向段落中心缩进

所有三个值的最初为 零.

调用 _GUICtrlRichEdit_SetSpaceUnit 函数设置 "空间单位". 最初为英寸

如果文本被选中,默认为第一选定段落的文本值.
如果没有选中,默认为当前段落的值.

相关

_GUICtrlRichEdit_GetParaIndents, _GUICtrlRichEdit_SetSpaceUnit

详情参考

在MSDN中搜索


示例/演示


#include <GuiRichEdit.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $lblMsg, $hRichEdit

Main()

Func Main()
    Local $hGui, $iMsg, $btnNext, $iStep = 0
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $lblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    $btnNext = GUICtrlCreateButton("Next", 270, 310, 40, 30)
    GUISetState()

    _GUICtrlRichEdit_SetText($hRichEdit, "First paragraph")
    Report("Para with default indent settings")

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; 除非脚本崩溃才需要
;~              GUIDelete()     ; 同样行
                Exit
            Case $iMsg = $btnNext
                $iStep += 1
                Switch $iStep
                    Case 1
                        _GUICtrlRichEdit_AppendText($hRichEdit, @CR & "Second paragraph")
                        Report("Added second paragraph")
                    Case 2
                        _GUICtrlRichEdit_SetParaIndents($hRichEdit, 0.25, .1)
                        Report("Changed indent settings of second paragraph")
                    Case 3
                        _GUICtrlRichEdit_SetSel($hRichEdit, 10, 26)
                        _GUICtrlRichEdit_SetParaIndents($hRichEdit, Default, 0, .2)
                        Report("Change settings of both paragraphs")
                    Case 4
                        ; Stream all text to the Desktop so you can look at Indents settings in Word
                        _GUICtrlRichEdit_Deselect($hRichEdit)
                        _GUICtrlRichEdit_StreamToFile($hRichEdit, @DesktopDir & "\gcre.rtf")
                        GUICtrlSetState($btnNext, $GUI_DISABLE)
                EndSwitch
        EndSelect
    WEnd
EndFunc   ;==>Main

Func Report($sMsg)
    $sMsg = $sMsg & @CR & @CR & "Get function returns " & @CR & _GUICtrlRichEdit_GetParaIndents($hRichEdit)
    GUICtrlSetData($lblMsg, $sMsg)
    ControlFocus($hRichEdit, "", "")
EndFunc   ;==>Report