函数参考

_GUICtrlTab_GetDisplayRect

检索客户区显示的矩形,返回数据数组.

#Include <GuiTab.au3>
_GUICtrlTab_GetDisplayRect($hWnd)

参数

$hWnd 控件句柄

返回值

成功: 数组的格式如下:
[0] = 矩形左上角 X 坐标
[1] = 矩形左上角 Y 坐标
[2] = 矩形右下角 X 坐标
[3] = 矩形右下角 Y 坐标

注意/说明

 此函数获取的坐标像素值,代表控件标签页面内的内容部分.
 当不同的标签被选中时,不会改变这部分选项卡控件的外观.

相关

_GUICtrlTab_GetDisplayRectEx

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiTab.au3>

$Debug_TAB = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $aRect, $sRect, $hTab

    ; 创建 GUI
    GUICreate("Tab Control Get Display Rect", 400, 300)
    $hTab = GUICtrlCreateTab(2, 2, 396, 296)
    GUISetState()

    ; 添加标签
    _GUICtrlTab_InsertItem($hTab, 0, "Tab 1")
    _GUICtrlTab_InsertItem($hTab, 1, "Tab 2")
    _GUICtrlTab_InsertItem($hTab, 2, "Tab 3")

    ; Get display rectangle
    $aRect = _GUICtrlTab_GetDisplayRect(GUICtrlGetHandle($hTab))
    $sRect = StringFormat("[%d, %d, %d, %d]", $aRect[0], $aRect[1], $aRect[2], $aRect[3])
    MsgBox(4160, "信息", "Display rectangle: " & $sRect)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main