函数参考


_GUICtrlTreeView_Create

创建一个树形查看(TreeView)控件

#Include <GuiTreeView.au3>
_GUICtrlTreeView_Create($hWnd, $iX, $iY[, $iWidth=150[, $iHeight=150[, $iStyle=0x00000037[, $iExStyle=0x00000000]]]])

参数

$hWnd 父窗口或者所有者窗口
$iX 控件水平坐标
$iY 控件垂直坐标
$iWidth [可选参数] 控件宽度
$iHeight [可选参数] 控件高度
$iStyle [可选参数] 控件样式:
DllStructGetData($TVS_CHECKBOXES - 项目启用复选框, "")
如果项目有关联的图像时显示复选框.
当设置为这种样式后,控件使用 DrawFrameControl
创建和设置包含两个图像状态的图像列表,
状态图像 1 为未选中复选框; 状态图像 2 为选中复选框
设置状态图像为 0, 则删除复选框
即使项目没有关联图像, 版本 5.80 也能显示复选框
$TVS_DISABLEDRAGDROP
阻止控件发送 $TVN_BEGINDRAG 通知消息
$TVS_EDITLABELS
允许用户修改该项目的标签
DllStructGetData($TVS_FULLROWSELECT - 允许全行选中, "")
选中项目的整行被突出显示
点击项目行的任何地方都将导致它被选中.
这种样式不能用于 DllStructGetData($TVS_HASLINES 样式, "")
DllStructGetData($TVS_HASBUTTONS - 父项目旁边显示加、减号按钮, "")
按钮点击可展开或折叠父项的子项列表
要点击根项目,还必须指定 DllStructGetData($TVS_LINESATROOT, "")
$TVS_HASLINES - 使用行显示项目的层次结构
$TVS_INFOTIP - 发送 $TVN_GETINFOTIP 通知获取工具提示信息
DllStructGetData($TVS_LINESATROOT - 根项目使用连接线, "")
此值被忽略,如果DllStructGetData($TVS_HASLINES 同样未指定, "")
DllStructGetData($TVS_NOHSCROLL - 禁用水平滚动 "")
控件不显示任何水平滚动条.
DllStructGetData($TVS_NONEVENHEIGHT - 与 $TVM_SETITEMHEIGHT 消息一起设置项目为奇数高度, "")
默认项目高度必须是偶数值
DllStructGetData($TVS_NOSCROLL - 禁用水平和垂直滚动 "")
控件将不显示任何滚动条.
$TVS_NOTOOLTIPS - 禁用工具提示
$TVS_RTLREADING - 由右至左显示文字
$TVS_SHOWSELALWAYS - 当控件失去焦点时,选中项目仍然保持选中状态
$TVS_SINGLEEXPAND - 项目被选中时将展开,未选择时折叠
如果鼠标单击处于折叠状态的项目,该项目将自动展开
如果按住 Ctrl 键的同时选择项目,该项目被取消选中状态不会折叠
版本 5.80 使项目被选中时展开,未选择时折叠
如果按住 Ctrl 键的同时选择项目,该项目被取消选中状态不会折叠.
$TVS_TRACKSELECT - 启用热跟踪
[可选参数] 默认 : $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT,
$TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS
强制 : $WS_CHILD, $WS_VISIBLE
$iExStyle [可选参数] 控件扩展样式

返回值

成功: 控件句柄
失败: 0

注意/说明

 此功能为高级用户学习如何控制工程

相关

_GUICtrlTreeView_Destroy

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

Global $hTreeView

_Main()

Func _Main()

    Local $GUI, $hItem
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
    $GUI = GUICreate("(UDF Created) TreeView Create", 400, 300)

    $hTreeView = _GUICtrlTreeView_Create($GUI, 2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 1 To Random(2, 10, 1)
        $hItem = _GUICtrlTreeView_Add($hTreeView, 0, StringFormat("[%02d] New Item", $x))
        For $y = 1 To Random(2, 10, 1)
            _GUICtrlTreeView_AddChild($hTreeView, $hItem, StringFormat("[%02d] New Child", $y))
        Next
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndTreeview
    $hWndTreeview = $hTreeView
    If Not IsHWnd($hTreeView) Then $hWndTreeview = GUICtrlGetHandle($hTreeView)

    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndTreeview
            Switch $iCode
                Case $NM_CLICK ; 用户在控件中点击了鼠标左键
                    _DebugPrint("$NM_CLICK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
;~                  Return 1 ; 非零值以不允许进行默认处理
                    Return 0 ; 零则允许进行默认处理
                Case $NM_DBLCLK ; 用户在控件中双击了鼠标左键
                    _DebugPrint("$NM_DBLCLK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
;~                  Return 1 ; 非零值以不允许进行默认处理
                    Return 0 ; 零则允许进行默认处理
                Case $NM_RCLICK ; 用户在控件中点击了鼠标右键
                    _DebugPrint("$NM_RCLICK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
;~                  Return 1 ; 非零值以不允许进行默认处理
                    Return 0 ; 零则允许进行默认处理
                Case $NM_RDBLCLK ; 用户在控件中点击了鼠标右键
                    _DebugPrint("$NM_RDBLCLK" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
;~                  Return 1 ; 非零值以不允许进行默认处理
                    Return 0 ; 零则允许进行默认处理
                Case $NM_KILLFOCUS ; 控件失去了输入焦点
                    _DebugPrint("$NM_KILLFOCUS" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; 没有返回值
                Case $NM_RETURN ; 控件有输入焦点且用户按下了此键
                    _DebugPrint("$NM_RETURN" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
;~                  Return 1 ; 非零值以不允许进行默认处理
                    Return 0 ; 零则允许进行默认处理
;~              Case $NM_SETCURSOR ; 控件正设置光标以响应 WM_SETCURSOR 消息
;~                  Local $tinfo = DllStructCreate($tagNMMOUSE, $ilParam)
;~                  $hWndFrom = HWnd(DllStructGetData($tinfo, "hWndFrom"))
;~                  $iIDFrom = DllStructGetData($tinfo, "IDFrom")
;~                  $iCode = DllStructGetData($tinfo, "Code")
;~                  _DebugPrint("$NM_SETCURSOR" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
;~                          "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
;~                          "-->Code:" & @TAB & $iCode & @LF & _
;~                          "-->ItemSpec:" & @TAB & DllStructGetData($tinfo, "ItemSpec") & @LF & _
;~                          "-->ItemData:" & @TAB & DllStructGetData($tinfo, "ItemData") & @LF & _
;~                          "-->X:" & @TAB & DllStructGetData($tinfo, "X") & @LF & _
;~                          "-->Y:" & @TAB & DllStructGetData($tinfo, "Y") & @LF & _
;~                          "-->HitInfo:" & @TAB & DllStructGetData($tinfo, "HitInfo"))
;~                  Return 0 ; 启用控件设置光标
;~                  Return 1 ; 非零值以阻止控件设置光标
                Case $NM_SETFOCUS ; 控件接收到输入焦点
                    _DebugPrint("$NM_SETFOCUS" & @LF & "--> hWndFrom:" & @TAB & $hWndFrom & @LF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @LF & _
                            "-->Code:" & @TAB & $iCode)
                    ; 没有返回值
                Case $TVN_BEGINDRAGA, $TVN_BEGINDRAGW
                    _DebugPrint("$TVN_BEGINDRAG")
                Case $TVN_BEGINLABELEDITA, $TVN_BEGINLABELEDITW
                    _DebugPrint("$TVN_BEGINLABELEDIT")
                Case $TVN_BEGINRDRAGA, $TVN_BEGINRDRAGW
                    _DebugPrint("$TVN_BEGINRDRAG")
                Case $TVN_DELETEITEMA, $TVN_DELETEITEMW
                    _DebugPrint("$TVN_DELETEITEM")
                Case $TVN_ENDLABELEDITA, $TVN_ENDLABELEDITW
                    _DebugPrint("$TVN_ENDLABELEDIT")
                Case $TVN_GETDISPINFOA, $TVN_GETDISPINFOW
                    _DebugPrint("$TVN_GETDISPINFO")
                Case $TVN_GETINFOTIPA, $TVN_GETINFOTIPW
                    _DebugPrint("$TVN_GETINFOTIP")
                Case $TVN_ITEMEXPANDEDA, $TVN_ITEMEXPANDEDW
                    _DebugPrint("$TVN_ITEMEXPANDED")
                Case $TVN_ITEMEXPANDINGA, $TVN_ITEMEXPANDINGW
                    _DebugPrint("$TVN_ITEMEXPANDING")
                Case $TVN_KEYDOWN
                    _DebugPrint("$TVN_KEYDOWN")
                Case $TVN_SELCHANGEDA, $TVN_SELCHANGEDW
                    _DebugPrint("$TVN_SELCHANGED")
                Case $TVN_SELCHANGINGA, $TVN_SELCHANGINGW
                    _DebugPrint("$TVN_SELCHANGING")
                Case $TVN_SETDISPINFOA, $TVN_SETDISPINFOW
                    _DebugPrint("$TVN_SETDISPINFO")
                Case $TVN_SINGLEEXPAND
                    _DebugPrint("$TVN_SINGLEEXPAND")
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Func _DebugPrint($s_text, $line = @ScriptLineNumber)
    ConsoleWrite( _
            "!===========================================================" & @LF & _
            "+======================================================" & @LF & _
            "-->Line(" & StringFormat("%04d", $line) & "):" & @TAB & $s_text & @LF & _
            "+======================================================" & @LF)
EndFunc   ;==>_DebugPrint