函数参考

_GUICtrlTreeView_GetFirstVisible

检索第一可见项目

#include <GuiTreeView.au3>
_GUICtrlTreeView_GetFirstVisible($hWnd)

参数

$hWnd 控件ID/句柄

返回值

成功: 返回第一可见项目句柄
失败: 返回 0

注意/说明

None.

相关

_GUICtrlTreeView_GetFirstItem

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()

    Local $hItem, $hFirst, $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Get First Visible", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To 20
        $hItem = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $hTreeView)
        For $y = 0 To 2
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $y), $hItem)
        Next
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    _GUICtrlTreeView_EnsureVisible($hTreeView, $hItem)
    $hFirst = _GUICtrlTreeView_GetFirstVisible($hTreeView)
    MsgBox(4160, "信息", "First Visible: " & $hFirst)
    _GUICtrlTreeView_SelectItem($hTreeView, $hFirst)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main