函数参考


_GUICtrlTreeView_SetBold

设置项目的粗体文本样式

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetBold($hWnd, $hItem [, $fFlag = True])

参数

$hWnd 控件ID/句柄
$hItem 项目句柄
$fFlag [可选参数] 如为 True,则使用粗体文本, 否则为 False

返回值

成功: True
失败: False

注意/说明

None.

相关

_GUICtrlTreeView_GetBold

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()

    Local $hItem[6], $hRandomItem, $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Set Bold", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To UBound($hItem) - 1
        $hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x + 1), $hTreeView)
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    $hRandomItem = Random(0, UBound($hItem) - 1, 1)
    MsgBox(4160, "信息", StringFormat("Item %d Bold? %s", $hRandomItem, _GUICtrlTreeView_GetBold($hTreeView, $hItem[$hRandomItem])))
    _GUICtrlTreeView_SetBold($hTreeView, $hItem[$hRandomItem])
    MsgBox(4160, "信息", StringFormat("Item %d Bold? %s", $hRandomItem, _GUICtrlTreeView_GetBold($hTreeView, $hItem[$hRandomItem])))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main