函数参考

_GUICtrlTreeView_SetIcon

设置项目图标

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetIcon($hWnd [, $hItem = 0 [, $sIconFile ="" [, $iIconID = 0 [, $iImageMode = 6]]]])

参数

$hWnd 控件ID/句柄
$hItem [可选参数] 项目 ID/句柄
$sIconFile [可选参数] 图标文件
$iIconID [可选参数] 图标文件中的图标 ID
$iImageMode [可选参数] 2 = 标准图像 / 4 = 选择图像设置

返回值

成功: 返回 True
失败: 返回 False

注意/说明

None.

相关

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

$Debug_TV = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()

    Local $hItem[10], $hTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS)

    GUICreate("TreeView Set Icon", 400, 300)

    $hTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState()

    _GUICtrlTreeView_BeginUpdate($hTreeView)
    For $x = 0 To 9
        $hItem[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $hTreeView)
        _GUICtrlTreeView_SetIcon($hTreeView, $hItem[$x], "shell32.dll", 3)
        For $y = 1 To 3
            GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Child", $y), $hItem[$x])
        Next
    Next
    _GUICtrlTreeView_EndUpdate($hTreeView)

    _GUICtrlTreeView_SetIcon($hTreeView, $hItem[0], "shell32.dll", 4)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main