在浏览器中执行预定义的一些简单操作.
#include <IE.au3>
_IEAction ( ByRef $o_object, $s_action )
| $o_object | 指向 InternetExplorer.Application 的对象变量 |
| $s_action | 操作选择 (参考备注) |
| 成功: | 返回 1 |
| 失败: | 返回 0 并设置 @ERROR |
| @Error: | 0 ($_IEStatus_Success) = 没有错误 |
| 3 ($_IEStatus_InvalidDataType) = 无效数据类型 | |
| 4 ($_IEStatus_InvalidObjectType) = 无效对象类型 | |
| 5 ($_IEStatus_InvalidValue) = 无效值 | |
| @Extended: | 包含无效参数的数量 |
| 操作 | 详细信息 |
| "back" | 按照历史列表转到后退页. |
| "blur" | 使元素失去焦点, 但是不会设置焦点到Tab顺序的下一个元素. |
| "click" | 模拟点击指定元素. |
| "copy" | 复制当前选择内容到剪切板. |
| "cut" | 复制当前选择内容到剪切板并删除所选内容. |
| "delete" | 删除当前所选内容. |
| "disable" | 禁用指定元素. |
| "enable" | 启用指定元素. |
| "focus" | 让指定元素接受焦点. |
| "forward" | 按照历史列表转到前进页. |
| "home" | 转到当前主页或者开始页. |
| "invisible" | 设置对象状态为隐藏. |
| "paste" | 覆盖当前所选内容为剪切板中的内容. |
| "print" | 打开打印对话框使用户可以打印当前页. |
| "printdefault" | 使用默认打印机直接打印当前页(不显示对话框) |
| "quit" | 关闭对象. |
| "refresh" | 刷新当前文档. |
| "saveas" | 打开一个对话框保存当前网页为一个文件. |
| "search" | 转到当前搜索页. |
| "selectall" | 选择整个文档. |
| "stop" | 取消任何进行中的转向或者下载操作并停止任何动态页元素, 例如背景声音和动画. |
| "unselect" | 清除当前所选. |
| "visible" | 设置对象状态为可见. |
; *******************************************************
; 示例 1 - 打开含 "表单" 示例的浏览器, 通过名称
; 获取到提交按钮的引用并 "点击" 它. 这种提交
; 表单的方法很有用, 因为许多表单依赖于 JavaScript
; 代码和在提交按钮上 "onClick" 事件使得 _IEFormSubmit()
; 不能像预期一样执行
; *******************************************************
#include <IE.au3>
Local $oIE = _IE_Example("form")
Local $oSubmit = _IEGetObjByName($oIE, "submitExample")
_IEAction($oSubmit, "click")
_IELoadWait($oIE)
; *******************************************************
; 示例 2 - 如同示例 1, 但不使用点击, 而是设置焦点到元素上
; 然后使用 ControlSend 发送回车当浏览器端的脚本
; 与点击动作关联时使用这种方法会阻止控件
; 自动返回到您的代码.
; *******************************************************
#include <IE.au3>
$oIE = _IE_Example("form")
$oSubmit = _IEGetObjByName($oIE, "submitExample")
Local $hwnd = _IEPropertyGet($oIE, "hwnd")
_IEAction($oSubmit, "focus")
ControlSend($hwnd, "", "[CLASS:Internet Explorer_Server; INSTANCE:1]", "{Enter}")
; 等待警告窗口, 然后点击 OK
WinWait("Windows Internet Explorer", "ExampleFormSubmitted")
ControlClick("Windows Internet Explorer", "ExampleFormSubmitted", "[CLASS:Button; TEXT:OK; Instance:1;]")
_IELoadWait($oIE)