为什么工具栏图标点击后，没有触发相应事件？（已解决）
本帖最后由 damoo 于 2014-3-24 14:14 编辑为什么工具栏图标点击后，没有触发相应事件。请哪位大大指点一下。谢谢。
#include <GuiToolbar.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
$Debug_TB = False ; 检查传递给函数的类名, 设置为 True, 并使用另一个控件句柄, 查看它的工作
_Main()
Func _Main()
Local $hGUI, $hToolbar, $aStrings
Local Enum $idNew = 1000, $idOpen, $idSave, $idHelp
; 创建 GUI
$hGUI = GUICreate("工具栏(Toolbar)控件 UDF 函数演示", 400, 300)
$hToolbar = _GUICtrlToolbar_Create($hGUI)
GUISetState()
; 添加标准系统位图
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
; 添加字符串
$aStrings = _GUICtrlToolbar_AddString($hToolbar, "新建 &N")
$aStrings = _GUICtrlToolbar_AddString($hToolbar, "打开 &O")
$aStrings = _GUICtrlToolbar_AddString($hToolbar, "保存 &S")
$aStrings = _GUICtrlToolbar_AddString($hToolbar, "帮助")
; 添加按钮
$btnNew = _GUICtrlToolbar_AddButton($hToolbar, $idNew, $STD_FILENEW, $aStrings)
_GUICtrlToolbar_AddButton($hToolbar, $idOpen, $STD_FILEOPEN, $aStrings)
_GUICtrlToolbar_AddButton($hToolbar, $idSave, $STD_FILESAVE, $aStrings)
_GUICtrlToolbar_AddButtonSep($hToolbar)
_GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP, $aStrings)
GUICtrlSetOnEvent($btnNew, "_btnNew")
; 循环到用户退出
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
Func _btnNew()
MsgBox(2262208,0,"This is new ...")
EndFunc
本帖最后由 pk196371 于 2014-3-24 12:09 编辑
#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $hToolbar, $iMemo
Global $iItem ; Command identifier of the button associated with the notification.
Global Enum $id_New = 1000, $id_Open, $id_Save, $id_Help
Example()
Func Example()
Local $hGUI, $aSize, $aStrings
; Create GUI
$hGUI = GUICreate("Toolbar", 600, 400)
$hToolbar = _GUICtrlToolbar_Create($hGUI)
$aSize = _GUICtrlToolbar_GetMaxSize($hToolbar)
$iMemo = GUICtrlCreateEdit("", 2, $aSize + 30, 596, 396 - ($aSize + 30), $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState(@SW_SHOW)
GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")
; Add standard system bitmaps
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
; Add strings
$aStrings = _GUICtrlToolbar_AddString($hToolbar, "&New")
$aStrings = _GUICtrlToolbar_AddString($hToolbar, "&Open")
$aStrings = _GUICtrlToolbar_AddString($hToolbar, "&Save")
$aStrings = _GUICtrlToolbar_AddString($hToolbar, "&Help")
; Add buttons
_GUICtrlToolbar_AddButton($hToolbar, $id_New, $STD_FILENEW, $aStrings)
_GUICtrlToolbar_AddButton($hToolbar, $id_Open, $STD_FILEOPEN, $aStrings)
_GUICtrlToolbar_AddButton($hToolbar, $id_Save, $STD_FILESAVE, $aStrings)
_GUICtrlToolbar_AddButtonSep($hToolbar)
_GUICtrlToolbar_AddButton($hToolbar, $id_Help, $STD_HELP, $aStrings)
; Click Save button using accelerator
_GUICtrlToolbar_ClickButton($hToolbar, $id_Save, "left", True)
; Loop until the user exits.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>Example
; Write message to memo
Func MemoWrite($sMessage = "")
GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc ;==>MemoWrite
; WM_NOTIFY event handler
Func _WM_NOTIFY($hWndGUI, $MsgID, $wParam, $lParam)
#forceref $hWndGUI, $MsgID, $wParam
Local $tNMHDR, $hwndFrom, $code, $i_idNew, $dwFlags, $i_idOld
Local $tNMTBHOTITEM
$tNMHDR = DllStructCreate($tagNMHDR, $lParam)
$hwndFrom = DllStructGetData($tNMHDR, "hWndFrom")
$code = DllStructGetData($tNMHDR, "Code")
Switch $hwndFrom
Case $hToolbar
Switch $code
Case $NM_LDOWN
;----------------------------------------------------------------------------------------------
;MemoWrite("$NM_LDOWN: Clicked Item: " & $iItem & " at index: " & _GUICtrlToolbar_CommandToIndex($hToolbar, $iItem))
;----------------------------------------------------------------------------------------------
Switch $iItem
Case 1000
;----------------------------------------------------------------------------------------------
MsgBox(0, "你点击了：", "New Button")
;----------------------------------------------------------------------------------------------
Case 1001
;----------------------------------------------------------------------------------------------
MsgBox(0, "你点击了：", "Open Button")
;----------------------------------------------------------------------------------------------
Case 1002
;----------------------------------------------------------------------------------------------
MsgBox(0, "你点击了：", "Save Button")
;----------------------------------------------------------------------------------------------
Case 1003
;----------------------------------------------------------------------------------------------
MsgBox(0, "你点击了：", "Help Button")
;----------------------------------------------------------------------------------------------
EndSwitch
Case $TBN_HOTITEMCHANGE
$tNMTBHOTITEM = DllStructCreate($tagNMTBHOTITEM, $lParam)
$i_idOld = DllStructGetData($tNMTBHOTITEM, "idOld")
$i_idNew = DllStructGetData($tNMTBHOTITEM, "idNew")
$iItem = $i_idNew
$dwFlags = DllStructGetData($tNMTBHOTITEM, "dwFlags")
If BitAND($dwFlags, $HICF_LEAVING) = $HICF_LEAVING Then
MemoWrite("$HICF_LEAVING: " & $i_idOld)
Else
Switch $i_idNew
Case $id_New
;----------------------------------------------------------------------------------------------
MemoWrite("$TBN_HOTITEMCHANGE: $idNew")
;----------------------------------------------------------------------------------------------
Case $id_Open
;----------------------------------------------------------------------------------------------
MemoWrite("$TBN_HOTITEMCHANGE: $idOpen")
;----------------------------------------------------------------------------------------------
Case $id_Save
;----------------------------------------------------------------------------------------------
MemoWrite("$TBN_HOTITEMCHANGE: $idSave")
;----------------------------------------------------------------------------------------------
Case $id_Help
;----------------------------------------------------------------------------------------------
MemoWrite("$TBN_HOTITEMCHANGE: $idHelp")
;----------------------------------------------------------------------------------------------
EndSwitch
EndIf
EndSwitch
EndSwitch
Return $GUI_RUNDEFMSG
EndFunc ;==>_WM_NOTIFY
回复 2# pk196371
兄弟，帮我再说的明确点。我还是没实现那个功能。接触AutoIT时间不长。谢谢。 回复 3# damoo
你先看下示例吧。 回复 4# pk196371
多谢pk196371，帮了我大忙。
按你的代码，我把它稍稍修改了下：
#include <GuiToolbar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $hToolbar, $iMemo
Global $iItem ; Command identifier of the button associated with the notification.
Global Enum $id_New = 1000, $id_Open, $id_Save, $id_Help
Example()
Func Example()
Local $hGUI, $aSize, $aStrings
; Create GUI
$hGUI = GUICreate("Toolbar", 600, 400)
$hToolbar = _GUICtrlToolbar_Create($hGUI)
$aSize = _GUICtrlToolbar_GetMaxSize($hToolbar)
$iMemo = GUICtrlCreateEdit("", 2, $aSize + 30, 596, 396 - ($aSize + 30), $WS_VSCROLL)
GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
GUISetState(@SW_SHOW)
GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")
; Add standard system bitmaps
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
; Add strings
$aStrings = _GUICtrlToolbar_AddString($hToolbar, "&New")
$aStrings = _GUICtrlToolbar_AddString($hToolbar, "&Open")
$aStrings = _GUICtrlToolbar_AddString($hToolbar, "&Save")
$aStrings = _GUICtrlToolbar_AddString($hToolbar, "Help")
; Add buttons
_GUICtrlToolbar_AddButton($hToolbar, $id_New, $aStrings, $aStrings)
_GUICtrlToolbar_AddButton($hToolbar, $id_Open, $aStrings, $aStrings)
_GUICtrlToolbar_AddButton($hToolbar, $id_Save, $aStrings, $aStrings)
_GUICtrlToolbar_AddButtonSep($hToolbar)
_GUICtrlToolbar_AddButton($hToolbar, $id_Help, $aStrings, $aStrings)
;_GUICtrlToolbar_ClickButton($hToolbar, $id_Save, "left", True)
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>Example
; WM_NOTIFY event handler
Func _WM_NOTIFY($hWndGUI, $MsgID, $wParam, $lParam)
#forceref $hWndGUI, $MsgID, $wParam
Local $tNMHDR, $hwndFrom, $code, $i_idNew, $dwFlags, $i_idOld
Local $tNMTBHOTITEM
$tNMHDR = DllStructCreate($tagNMHDR, $lParam)
$hwndFrom = DllStructGetData($tNMHDR, "hWndFrom")
$code = DllStructGetData($tNMHDR, "Code")
Switch $hwndFrom
Case $hToolbar
Switch $code
Case $NM_LDOWN
Switch $iItem
Case 1000
MsgBox(262208, "你点击了：", "New Button")
Case 1001
MsgBox(262208, "你点击了：", "Open Button")
Case 1002
MsgBox(262208, "你点击了：", "Save Button")
Case 1003
MsgBox(262208, "你点击了：", "Help Button")
EndSwitch
Case $TBN_HOTITEMCHANGE
$tNMTBHOTITEM = DllStructCreate($tagNMTBHOTITEM, $lParam)
$i_idOld = DllStructGetData($tNMTBHOTITEM, "idOld")
$i_idNew = DllStructGetData($tNMTBHOTITEM, "idNew")
$iItem = $i_idNew
$dwFlags = DllStructGetData($tNMTBHOTITEM, "dwFlags")
EndSwitch
EndSwitch
Return $GUI_RUNDEFMSG
EndFunc ;==>_WM_NOTIFY
页:
[1]