[已解决]检查网络连接的一段代码，请大侠们帮我一下

fyq

在论坛学习了N久，学写了一段安装软件时先检查网络连接状态的代码，但执行效率不高，请大侠们帮我修改一下。
谢谢先
基本思路是：在安装软件前，先检查网络连接，如果网络是通的，就直接安装软件；
                  如果网络不通，就出现选择提示：
                  如果把网络连接后，点击重试按钮继续安装软件；
                  如果忽略网络连接，点击取消按钮安装软件。

Do
        Local $iPing = Ping("www.baidu.com")

        If $iPing Then
                Run(@ScriptDir & "\SySoftIns.exe")
        Else
                Local $str = "你的网络没有连接！\n\n请先连接网络，再单击【重试】安装软件。\n在断网状况下安装软件，可能会造成部分软件不能安装或其他不可预知的问题！\n\n单击【重试】：将重新连接网络安装软件；\n单击【取消】：将忽略网络连接状态继续安装软件。\n\n\n请选择："

                Switch MsgBox(270389, "警告－－网络不通", StringFormat($str))
                        
                        Case 4
                                If $iPing Then
                                        Run(@ScriptDir & "\SySoftIns.exe")
                                EndIf
                                
                        Case 2
                                Run(@ScriptDir & "\SySoftIns.exe")
                EndSwitch
                
        EndIf
Until ProcessExists("SySoftIns.exe")

lxz

期待高人出现.

zch11230

我觉得这没什么效率的吧 也循环不了多少次 能实现功能就好

Do
        If Ping("www.baidu.com") Then
                Run("notepad.exe")
                ExitLoop
        EndIf
Until MsgBox(5, "警告", "你的网络没有连接") = 2

考虑到有的时候万一网络卡了没PING通导致误报 多PING几次。

Do
        If _pingbd() Then
                Run("notepad.exe")
                ExitLoop
        EndIf
Until MsgBox(5, "警告", "你的网络没有连接") = 2

Func _pingbd()
        Local $n
        Do
                If Ping("www.baidu.com") Then Return True
                $n += 1
        Until $n > 5
        Return False
EndFunc 

fyq

我觉得这没什么效率的吧 也循环不了多少次 能实现功能就好考虑到有的时候万一网络卡了没PING通导致误报 多P ...
zch11230 发表于 2013-10-7 21:19

    多谢了，测试一下

linguanshou

我记得可以用下载百度的ICO或谷歌的ICO来测试网络。。

东风破

回复 3# zch11230

额。。。感觉还是不要用ping吧，虽然我也感觉它很效率。但是若是局域网-网关开启防ping的时候就不起作用了（比如我上班的地方，上网一切操作没问题，但就是ping不通任何网站）
所以我一直这样检测网络：

Func CheckOnline()
        If TCPNameToIP("www.baidu.com") <> "" Then
                $sResault = 1
        Else
                $sResault = 0
        EndIf
        Return $sResault
EndFunc   ;==>CheckOnline

记得，运行时TCPStartup()，结束时TCPShutdown()

masterpcc

谢谢分享！

fyq

回复 6# 东风破


    多谢指教！！

虫子樱桃

$state=-1
While 1
    If _IsCon()<>$state Then 
        If _IsCon()=0 Then 
            TrayTip("Internet Connection","Disconnected",2,2) 
            $state=0
        Else 
            TrayTip("Internet Connection","Connected",2,1) 
            $state=1
        EndIf 
   
    Else 
    EndIf 
WEnd 
   
Func _IsCon() 
    $IsCon=DllCall("WinInet.dll","int","InternetGetConnectedState","int_ptr",0,"int",0) 
    Return $iscon[0] 
EndFunc 
  

fyq

虫子樱桃 发表于 2013-10-10 13:12

    受宠若惊啊，没想到惊动了虫子樱桃大师

netegg

#Include <WinAPIEx.au3>
_WinAPI_IsInternetConnected( )
#Include <WinINet.au3>
_WinINet_InternetCheckConnection( [$sUrl = Default[, $iFlags = 0]] )

lanfengc

回复 10# 虫子樱桃


    这个代码检测的到互联网状态吗？ 检测的只是本地网卡状态吧？

mikezunya

先可以ping下www.baidu.com 拿到他的返回结果，如果通，就装，如果不通弹出msgbox框，再根据用户点击的按钮，反悔ID。来判断是忽略，还是终止，还是继续。然后后面的自己写了。思路就是这样