OnEvent模式进阶教程

zcbenz

很多autoit的用户（包括一些老用户）都认为OnEvent模式是简单的把GUIGetMsg 替换成了GUICtrlSetOnEvent，因此也产生了OnEvent模式不适合复杂GUI的误解。本文将具体阐述OnEvent模式的高级应用和使用技巧。

一、OnEvent模式的优势

OnEvent模式和MessageLoop模式最大的区别在于一个是主动，一个是被动。前者只有产生了消息才会执行函数，而后者则是不断地获取直到得到消息，这样CPU占用上OnEvent模式有很大优势。

另外，OnEvent模式能在运行脚本的同时获取GUI事件消息，这样我们就能把非常耗时的代码放在主循环里运行，而在其他的自定义函数里处理GUI消息。

比如下面这段代码，程序一直在主循环里更新控件内容，与此同时程序还能响应GUI消息：

1. #include <GuiConstants.au3>
   
2. 
   
3. GUICreate("MyGUI", 372, 88, -1, -1, BitOR($WS_OVERLAPPEDWINDOW, $WS_CLIPSIBLINGS))
   
4. 
   
5. $Progress_1 = GUICtrlCreateProgress(10, 10, 370, 20)
   
6. $Button_2 = GUICtrlCreateButton("start", 10, 40, 60, 30)
   
7. $Button_3 = GUICtrlCreateButton("pause", 80, 40, 60, 30)
   
8. $Button_4 = GUICtrlCreateButton("exit", 150, 40, 70, 30)
   
9. 
   
10. Opt("GUIOnEventMode", 1)
    
11. 
    
12. Dim $start = 0, $ostart
    
13. 
    
14. GUISetState()
    
15. GUISetOnEvent($GUI_EVENT_CLOSE, "gui")
    
16. GUICtrlSetOnEvent($Button_2, "gui")
    
17. GUICtrlSetOnEvent($Button_3, "gui")
    
18. GUICtrlSetOnEvent($Button_4, "gui")
    
19. 
    
20. While 1
    
21.     If $start >= 0 Then
    
22.         Sleep(50)
    
23.         $start += 1
    
24.         If $start > 100 Then $start = 0
    
25.         If $start >= 0 Then
    
26.             $ostart = $start
    
27.             GUICtrlSetData($Progress_1, $start)
    
28.         Else
    
29.             ContinueLoop
    
30.         EndIf
    
31.     EndIf
    
32. WEnd
    
33. 
    
34. Exit
    
35. 
    
36. Func gui()
    
37.     Switch @GUI_CtrlId
    
38.         Case $GUI_EVENT_CLOSE, $Button_4
    
39.             Exit
    
40.         Case $Button_2
    
41.             $start = 0
    
42.         Case $Button_3
    
43.             If $start = -100 Then
    
44.                 $start = $ostart
    
45.             Else
    
46.                 $start = -100
    
47.             EndIf
    
48.     EndSwitch
    
49. EndFunc   ;==>gui

复制代码

如果用MessageLoop模式来实现相同的效果，不但代码复杂，对GUI消息的响应也相当迟钝。也就是说MessageLoop模式只能在一个时间里做一件事，而OnEvent模式则能在做同样的事的同时抽出手去处理GUI事件。

所以，对于一些操作非常耗时或者GUI非常复杂的脚本，我们应首选OnEvent模式。

二、宏的妙用

许多人都有一个误解，认为一个事件只能注册一个函数，因此一些人把脚本写完之后代码里到处都是Func 、EndFunc。实际上，autoit本就提供了@GUI_CTRLID、@GUI_WINHANDLE、@GUI_CTRLHANDLE这三个宏，合理利用宏能大大简化代码

事实上，帮助文件里就有过说明：

注意：使用同一个函数来响应多种事件是完全合法的，记住要灵活使用 @GUI_CTRLID 这个宏。比如说，您可以注册所有系统事件到同一个函数。


下面是一个例子：

1. #include <GuiConstants.au3>
   
2. 
   
3. GuiCreate("MyGUI", 340, 60,-1, -1 , BitOR($WS_OVERLAPPEDWINDOW, $WS_CLIPSIBLINGS))
   
4. 
   
5. $Button_1 = GuiCtrlCreateButton("Button1", 10, 10, 100, 40)
   
6. $Button_2 = GuiCtrlCreateButton("Button2", 120, 10, 100, 40)
   
7. $Button_3 = GuiCtrlCreateButton("Button3", 230, 10, 100, 40)
   
8. 
   
9. Opt("GUIOnEventMode", 1)
   
10. 
    
11. 
    
12. GUISetState()
    
13. 
    
14. GUISetOnEvent($GUI_EVENT_CLOSE, "gui")
    
15. GUICtrlSetOnEvent($Button_2, "gui")
    
16. GUICtrlSetOnEvent($Button_3, "gui")
    
17. GUICtrlSetOnEvent($Button_1, "gui")
    
18. 
    
19. While 1
    
20.     ;;;
    
21. WEnd
    
22. 
    
23. Exit
    
24. 
    
25. Func gui()
    
26.     Switch @GUI_CtrlId
    
27.         Case $GUI_EVENT_CLOSE
    
28.             Exit
    
29.         Case $Button_2
    
30.             MsgBox(0,"","按下了Button_2")
    
31.         Case $Button_3
    
32.             MsgBox(0,"","按下了Button_3")
    
33.         Case $Button_1
    
34.             MsgBox(0,"","按下了Button_1")
    
35.     EndSwitch
    
36. EndFunc   ;==>gui

复制代码

在上面的例子里，我将全部的事件都注册到一个函数里，然后根据@GUI_CTRLID来判断具体的事件，这样代码就简洁多了。

而在关闭多窗口时@GUI_WINHANDLE则会起到很大作用，下面有个例子：

1. #include <GuiConstants.au3>
   
2. Opt("GUIOnEventMode", 1)
   
3. 
   
4. $main = GuiCreate("MyGUI", 340, 60,-1, -1 , BitOR($WS_OVERLAPPEDWINDOW, $WS_CLIPSIBLINGS))
   
5. GUISetOnEvent($GUI_EVENT_CLOSE, "gui")
   
6. 
   
7. $Button_1 = GuiCtrlCreateButton("Button1", 10, 10, 100, 40)
   
8. $Button_2 = GuiCtrlCreateButton("Button2", 120, 10, 100, 40)
   
9. $Button_3 = GuiCtrlCreateButton("Button3", 230, 10, 100, 40)
   
10. 
    
11. GUISetState()
    
12. 
    
13. GuiCreate("子窗口1", 140, 60,10,100,-1,-1,$main)
    
14. GUISetOnEvent($GUI_EVENT_CLOSE, "gui")
    
15. GUISetState()
    
16. GuiCreate("子窗口2", 140, 60,160,100,-1,-1,$main)
    
17. GUISetOnEvent($GUI_EVENT_CLOSE, "gui")
    
18. GUISetState()
    
19. GuiCreate("子窗口3", 140, 60,300,100,-1,-1,$main)
    
20. GUISetOnEvent($GUI_EVENT_CLOSE, "gui")
    
21. GUISetState()
    
22. 
    
23. GUISetOnEvent($GUI_EVENT_CLOSE, "gui")
    
24. GUICtrlSetOnEvent($Button_2, "gui")
    
25. GUICtrlSetOnEvent($Button_3, "gui")
    
26. GUICtrlSetOnEvent($Button_1, "gui")
    
27. 
    
28. While 1
    
29.     ;;;
    
30. WEnd
    
31. 
    
32. Exit
    
33. 
    
34. Func gui()
    
35.     Switch @GUI_CtrlId
    
36.         Case $GUI_EVENT_CLOSE
    
37.             Switch @GUI_WINHANDLE
    
38.                 Case $main
    
39.                     Exit
    
40.                 Case Else
    
41.                     MsgBox(0,"","关闭窗口:"&WinGetTitle(@GUI_WINHANDLE))
    
42.                     GUIDelete(@GUI_WINHANDLE)
    
43.             EndSwitch
    
44.         Case $Button_2
    
45.             MsgBox(0,"","按下了Button_2")
    
46.         Case $Button_3
    
47.             MsgBox(0,"","按下了Button_3")
    
48.         Case $Button_1
    
49.             MsgBox(0,"","按下了Button_1")
    
50.     EndSwitch
    
51. EndFunc   ;==>gui

复制代码

我们可以看到，主窗口关闭时程序会直接退出，而其余窗口关闭时则会删掉关闭的窗口。这里有个技巧，就是对于非主窗口，我们可以在Case Else的情况下用GUIDelete(@GUI_WinHandle)直接处理窗口，而不需要为每个窗口都写一个关闭函数。

三、多窗口操作技巧

建立多窗口时两种选择，一是在脚本开头就建立好全部窗口，然后把多余的窗口隐藏起来，在需要时再将隐藏的窗口显示出来。二是只建立主窗口，在需要时才建立子窗口。前一种选择会多占用内存，但响应速度非常快，适合使用多个非常复杂的窗口的脚本；而后一种选择明显要节约内存，但临时建立窗口会花费一些时间，适合一些子窗口简单的脚本。

至于帮助文件里提到的GUISwitch函数，实际上很少会用到。

下面分别是两种选择的范例：
隐藏子窗口型：

1. #include <GuiConstants.au3>
   
2. Opt("GUIOnEventMode", 1)
   
3. 
   
4. $main = GuiCreate("MyGUI", 340, 60,-1, -1 , BitOR($WS_OVERLAPPEDWINDOW, $WS_CLIPSIBLINGS))
   
5. GUISetOnEvent($GUI_EVENT_CLOSE, "gui")
   
6. 
   
7. $Button_1 = GuiCtrlCreateButton("显示窗口1", 10, 10, 100, 40)
   
8. $Button_2 = GuiCtrlCreateButton("显示窗口2", 120, 10, 100, 40)
   
9. $Button_3 = GuiCtrlCreateButton("显示窗口3", 230, 10, 100, 40)
   
10. 
    
11. GUISetState()
    
12. 
    
13. $s1 = GuiCreate("子窗口1", 140, 60,10,100,-1,-1,$main)
    
14. GUISetOnEvent($GUI_EVENT_CLOSE, "gui")
    
15. GUISetState(@SW_HIDE)
    
16. $s2 = GuiCreate("子窗口2", 140, 60,160,100,-1,-1,$main)
    
17. GUISetOnEvent($GUI_EVENT_CLOSE, "gui")
    
18. GUISetState(@SW_HIDE)
    
19. $s3 = GuiCreate("子窗口3", 140, 60,300,100,-1,-1,$main)
    
20. GUISetOnEvent($GUI_EVENT_CLOSE, "gui")
    
21. GUISetState(@SW_HIDE)
    
22. 
    
23. GUISetOnEvent($GUI_EVENT_CLOSE, "gui")
    
24. GUICtrlSetOnEvent($Button_2, "gui")
    
25. GUICtrlSetOnEvent($Button_3, "gui")
    
26. GUICtrlSetOnEvent($Button_1, "gui")
    
27. 
    
28. While 1
    
29.     ;;;
    
30. WEnd
    
31. 
    
32. Exit
    
33. 
    
34. Func gui()
    
35.     Switch @GUI_CtrlId
    
36.         Case $GUI_EVENT_CLOSE
    
37.             Switch @GUI_WINHANDLE
    
38.                 Case $main
    
39.                     Exit
    
40.                 Case Else
    
41.                     GUISetState(@SW_HIDE,@GUI_WINHANDLE)
    
42.             EndSwitch
    
43.         Case $Button_2
    
44.             GUISetState(@SW_SHOW,$s2)
    
45.         Case $Button_3
    
46.             GUISetState(@SW_SHOW,$s3)
    
47.         Case $Button_1
    
48.             GUISetState(@SW_SHOW,$s1)
    
49.     EndSwitch
    
50. EndFunc   ;==>gui

复制代码

删除子窗口型：

1. #include <GuiConstants.au3>
   
2. Opt("GUIOnEventMode", 1)
   
3. 
   
4. $main = GuiCreate("MyGUI", 340, 60,-1, -1 , BitOR($WS_OVERLAPPEDWINDOW, $WS_CLIPSIBLINGS))
   
5. GUISetOnEvent($GUI_EVENT_CLOSE, "gui")
   
6. 
   
7. $Button_1 = GuiCtrlCreateButton("显示窗口1", 10, 10, 100, 40)
   
8. $Button_2 = GuiCtrlCreateButton("显示窗口2", 120, 10, 100, 40)
   
9. $Button_3 = GuiCtrlCreateButton("显示窗口3", 230, 10, 100, 40)
   
10. 
    
11. GUISetState()
    
12. GUISetOnEvent($GUI_EVENT_CLOSE, "gui")
    
13. 
    
14. GUICtrlSetOnEvent($Button_2, "gui")
    
15. GUICtrlSetOnEvent($Button_3, "gui")
    
16. GUICtrlSetOnEvent($Button_1, "gui")
    
17. 
    
18. While 1
    
19.     ;;;
    
20. WEnd
    
21. 
    
22. Exit
    
23. 
    
24. Func gui()
    
25.     Switch @GUI_CtrlId
    
26.         Case $GUI_EVENT_CLOSE
    
27.             Switch @GUI_WINHANDLE
    
28.                 Case $main
    
29.                     Exit
    
30.                 Case Else
    
31.                     GUIDelete(@GUI_WINHANDLE)
    
32.             EndSwitch
    
33.         Case $Button_2
    
34.             if WinExists("子窗口2") = 0 Then
    
35.                 GuiCreate("子窗口2", 140, 60,10,100,-1,-1,$main)
    
36.                 GUISetState()
    
37.                 GUISetOnEvent($GUI_EVENT_CLOSE, "gui")
    
38.             EndIf
    
39.         Case $Button_3
    
40.             if WinExists("子窗口3") = 0 Then
    
41.                 GuiCreate("子窗口3", 140, 60,160,100,-1,-1,$main)
    
42.                 GUISetState()
    
43.                 GUISetOnEvent($GUI_EVENT_CLOSE, "gui")
    
44.             EndIf
    
45.         Case $Button_1
    
46.             if WinExists("子窗口1") = 0 Then
    
47.                 GuiCreate("子窗口1", 140, 60,300,100,-1,-1,$main)
    
48.                 GUISetState()
    
49.                 GUISetOnEvent($GUI_EVENT_CLOSE, "gui")
    
50.             EndIf
    
51.     EndSwitch
    
52. EndFunc   ;==>gui

复制代码

四、一些技巧

除去上面几节提到的一些，OnEvent模式下还有几项实用的技巧：

1.可控下载

在下载时，我们可以把下载函数放到主循环里进行，再根据某个变量的变化来停止、开始下载。而我们可以根据不同的GUI事件来控制这个变量。下面是一个例子：

1. #include <GuiConstants.au3>
   
2. Opt("GUIOnEventMode", 1)
   
3. Dim $start,$stop
   
4. 
   
5. GuiCreate("MyGUI", 392, 84,-1, -1 , BitOR($WS_OVERLAPPEDWINDOW, $WS_CLIPSIBLINGS))
   
6. 
   
7. $Input_1 = GuiCtrlCreateInput("http://www.geocities.com/z8519312/ComicsDown-203.zip", 10, 10, 280, 30)
   
8. $Button_2 = GuiCtrlCreateButton("下载", 300, 10, 80, 30)
   
9. $Progress_3 = GuiCtrlCreateProgress(10, 50, 370, 20)
   
10. 
    
11. GUISetOnEvent($GUI_EVENT_CLOSE, "gui")
    
12. GUICtrlSetOnEvent($Button_2,"gui")
    
13. 
    
14. GuiSetState()
    
15. 
    
16. While 1
    
17.     If $start=1 Then
    
18.         GUICtrlSetData($Button_2,"停止")
    
19.         $url = GUICtrlRead($Input_1)
    
20.         $size = InetGetSize($url)
    
21.         InetGet ($url, @TempDir&"\d.tem",0,1)
    
22.         Do
    
23.             Sleep(500)
    
24.             GUICtrlSetData($Progress_3,@InetGetBytesRead /$size*100)
    
25.             If $stop = 1 Then
    
26.                 InetGet ("abort")
    
27.                 ExitLoop
    
28.             EndIf
    
29.         Until @InetGetActive = 0
    
30.         GUICtrlSetData($Button_2,"下载")
    
31.         $stop = 0
    
32.         $start = 0
    
33.     EndIf
    
34. WEnd
    
35. 
    
36. Exit
    
37. 
    
38. Func gui()
    
39.     Switch @GUI_CtrlId
    
40.         Case $GUI_EVENT_CLOSE
    
41.             Exit
    
42.         Case $Button_2
    
43.             If GUICtrlRead($Button_2) = "下载" Then
    
44.                 $start =1
    
45.             Else
    
46.                 $stop = 1
    
47.             EndIf
    
48.     EndSwitch
    
49. EndFunc

复制代码

2.用数组储存控件ID

有时候我们需要注册的大量控件，如果是每一个控件都用GUICtrlSetOnEvent来注册，代码量会非常大，这时用数组就会省事得多。下面是个例子：

1. Dim $Button[3]
   
2. 
   
3. $Button[0] = GuiCtrlCreateButton("Button1", 10, 10, 100, 40)
   
4. $Button[1] = GuiCtrlCreateButton("Button2", 120, 10, 100, 40)
   
5. $Button[2] = GuiCtrlCreateButton("Button3", 230, 10, 100, 40)
   
6. 
   
7. For $i =0 To 2
   
8. GUICtrlSetOnEvent($Button[$i], "gui")
   
9. Next

复制代码

这里有个问题，绝大多数人都使用KODA来建立窗口（其实我自己用的是GUIBuilder），而KODA不能以数组来命名控件ID，只能用button_1、button_2之类的名称来命名控件ID，这时我们就可以用Eval函数来解决：

1. $Button_1 = GuiCtrlCreateButton("Button1", 10, 10, 100, 40)
   
2. $Button_2 = GuiCtrlCreateButton("Button2", 120, 10, 100, 40)
   
3. $Button_3 = GuiCtrlCreateButton("Button3", 230, 10, 100, 40)
   
4. 
   
5. For $i =0 To 2
   
6. GUICtrlSetOnEvent(Eval("Button_"&String($i)), "gui")
   
7. Next

复制代码

——END——

bing614

这么好的贴没人顶呢?呵呵~!学习了,

vv3509

谢谢了,要好好研究哈

ylvip

这个帖子要顶。

itljl

谢谢！！谢谢！！

itljl

好东西。GUISetOnEvent

zgymmm123

好好学习 天天向上

难得糊涂

好好学习。。。

xgdjkk

不知道要学多久才有LZ到境界！！
  努力学习中！！

k1727

好好学习,天天向上.

sbyguli

好帖子啊，楼主，多出一些这样的教程

streamload

很实用，谢谢分享。。。

kodin

精华！讲得实在太好了，学习了！

cnsnc

真是好帖，支持下

waynelue

楼上是牛人，这都让你给翻出来了