求一句正则表达式，谢谢各位

765058729

Local $Stater = "[0]aa[1]bb[2]cc[3]dd[4]ee[5]tt[6]hk[7]lj[8]jj[9]kj[10]nnn"
        
若已知0，得到aa；已知1，得到bb；已知10得到nnn

3131210

#include <Array.au3>

Local $Stater  = '[0]aa[1]bb[2]cc[3]dd[4]ee[5]tt[6]hk[7]lj[8]jj[9]kj[10]nnn'


;找0
Local $f0 = StringRegExp($Stater , '\[' & 0 & '\](.+?)(?:\[|$)', 3)
If Not @Error Then ConsoleWrite('结果为: ' & $f0[0] & @CRLF)

;找1
Local $f1 = StringRegExp($Stater , '\[' & 1 & '\](.+?)(?:\[|$)', 3)
If Not @Error Then ConsoleWrite('结果为: ' & $f1[0] & @CRLF)

;找10
Local $f10 = StringRegExp($Stater , '\[' & 10 & '\](.+?)(?:\[|$)', 3)
If Not @Error Then ConsoleWrite('结果为: ' & $f10[0] & @CRLF)

;找全部
Local $fAll = StringRegExp($Stater , '\[\d+\]([a-zA-Z]+)', 3)
If Not @Error Then ConsoleWrite('结果为: ' & _ArrayToString($fAll) & @CRLF)

holley

Func GetValueByKey($sText, $iKey)
    Local $aRet = StringRegExp($sText, "\[" & $iKey & "\](.*?)(?=\[\d+\]|$)", 1)
    If @error Then Return ""
    Return $aRet[0]
EndFunc

Local $Stater = "[0]aa[1]bb[2]cc[3]dd[4]ee[5]tt[6]hk[7]lj[8]jj[9]kj[10]nnn"

ConsoleWrite(GetValueByKey($Stater, 0) & @CRLF)   ; aa
ConsoleWrite(GetValueByKey($Stater, 1) & @CRLF)   ; bb
ConsoleWrite(GetValueByKey($Stater, 10) & @CRLF)  ; nnn