_GUICtrlMenu_CreatePopup 参数 为何没有作用??[已解决]

kk_lee69

手册上说:
[可选参数] 菜单样式. 可以是一或多个下列值:
1 - 鼠标移出菜单10秒后, 菜单自动结束
2 - 为复选标记和位图保留同样的空间
4 - 菜单项目是 OLE 撤销目标或拖动源
8 - 无模式菜单
16 - 项目左侧不保留复选标记空间
32 - 菜单的所有者接收 WM_MENUCOMMAND 消息, 而不是 WM_COMMAND 选择消息

请看下面 范例 我加了 参数1  应该要 鼠标移出菜单10表后 自动结束
可是 不会呀  有人知道原因吗??


另外项目左侧 可以不要保留空间吗  应该是参数16的功能 可是好像一样不可以

#include <GuiMenu.au3>
#include <GuiConstantsEx.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Global Enum $idOpen = 1000, $idSave, $idInfo

_Main()

Func _Main()
    ; 创建 GUI
    GUICreate("菜单 UDF 函数演示", 400, 300)
    GUISetState()

    ; 注册消息处理程序
    GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")
    GUIRegisterMsg($WM_CONTEXTMENU, "WM_CONTEXTMENU")

    ; 循环到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; 处理 WM_COMMAND 命令消息
Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $ilParam
    Switch $iwParam
        Case $idOpen
            _WinAPI_ShowMsg ("点击 '打开'菜单")
        Case $idSave
            _WinAPI_ShowMsg ("点击 '保存'菜单")
        Case $idInfo
            _WinAPI_ShowMsg ("点击 '信息'菜单")
    EndSwitch
EndFunc   ;==>WM_COMMAND

; 处理 WM_CONTEXTMENU 消息
Func WM_CONTEXTMENU($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $ilParam
    Local $hMenu

    $hMenu = _GUICtrlMenu_CreatePopup(1)
    _GUICtrlMenu_InsertMenuItem($hMenu, 0, "打开", $idOpen)
    _GUICtrlMenu_InsertMenuItem($hMenu, 1, "保存", $idSave)
    _GUICtrlMenu_InsertMenuItem($hMenu, 3, "", 0)
    _GUICtrlMenu_InsertMenuItem($hMenu, 3, "信息", $idInfo)
    _GUICtrlMenu_TrackPopupMenu($hMenu, $iwParam)
    _GUICtrlMenu_DestroyMenu($hMenu)
    Return True
EndFunc   ;==>WM_CONTEXTMENU

afan

那几个参数值应该是错的
高版本有修改，该参数为常量 $MNS_AUTODISMISS = 0x10000000
离开菜单关闭应该是10ms

chzj589

回复 1# kk_lee69
旧版本帮助的参数有问题
[可选参数] 菜单样式. 可以是一或多个下列值:
1 - 鼠标移出菜单10秒后,菜单自动结束
2 - 为复选标记和位图保留同样的空间
4 - 菜单项目是 OLE 撤销目标或拖动源
8 - 无模式菜单
16 - 项目左侧不保留复选标记空间
32 - 菜单属主接收 WM_MENUCOMMAND 消息,而不是 WM_COMMAND 选择消息

用以下参数就可以
Global Const $MNS_CHECKORBMP = 0x04000000
Global Const $MNS_NOTIFYBYPOS = 0x08000000
Global Const $MNS_AUTODISMISS = 0x10000000
Global Const $MNS_DRAGDROP = 0x20000000
Global Const $MNS_MODELESS = 0x40000000
Global Const $MNS_NOCHECK = 0x80000000

kk_lee69

回复 2# afan

收到 了解  感謝解答

kk_lee69

回复 3# chzj589

收到 了解  感謝解答