进程间的七种通信方式

tubaba

当然，在处理收到的消息，也要用BinaryToString($vParameter, 4)进行还原

smooth

tubaba 发表于 2022-5-23 09:48
在用前辈研发的UDF函数时，可以仔细查看UDF的写法思路，这样才会提高自己的编程水平，如果你仔细研究copr ...

大佬你太强了。我看过这个函数，但是几乎看不懂，特别遇到DllStructCreate，不明白创建结构如何理解，看来得好好研究一下数据结构了。

smooth

tubaba 发表于 2022-5-23 10:02
当然，在处理收到的消息，也要用BinaryToString($vParameter, 4)进行还原

请教一下，发送消息的时候，为何要创建两个数据结构，我看着感觉创建一个数据结构，就可以把数据传递过去了，但是我没搞成。

;父进程向子进程发送消息
Func _SendData($hWndTarget, $sData) ;$hWndTarget：子进程窗口句柄。
     Local $msg = StringToBinary($sData, 4)  ;转换字符串为二进制数据，格式为UTF8 编码。参数4：字符串数据为 UTF8 编码
 
     Local $MyData = DllStructCreate("byte[" & BinaryLen($msg) & "]")  ;BinaryLen：返回二进制变量的字节数。byte：8 位(1字节) 无符号字符. UTF-8 编码单位. "汉字"的 UTF-8 编码需要6个字节.
     Local $COPYDATA = DllStructCreate("ptr;dword;ptr")
 
     DllStructSetData($MyData, 1, $msg)  ;设置数据结构元素的数据，第1个参数：结构变量，第2个参数：元素，第3个参数：值
     DllStructSetData($COPYDATA, 1, 0)
     DllStructSetData($COPYDATA, 2, DllStructGetSize($MyData))  ;返回数据结构的大小(字节)。
     DllStructSetData($COPYDATA, 3, DllStructGetPtr($MyData))  ;返回数据结构指针.
    
     Local $aTmp = DllCall("user32.dll", "int", "SendMessageTimeout", "hwnd", $hWndTarget, "int", $WM_COPYDATA, "int", 0, "ptr", DllStructGetPtr($COPYDATA), "int", 0, "int", 1000, "long*", 0)  ; WM_COPYDATA：0x004A
EndFunc   ;==>_SendData

smooth

tubaba 发表于 2022-5-20 16:44
先介绍第三种：消息队列MessageQueue

今天测试发现，如果如果传送的消息略频繁，比如半秒钟传递一次，则很容易（基本上确定会）导致消息堵塞，子进程卡死，导致程序无法正常工作。传递的消息并不大，编码格式为UTF8的BinaryLen长度，仅为44.

smooth

tubaba 发表于 2022-5-23 09:48
在用前辈研发的UDF函数时，可以仔细查看UDF的写法思路，这样才会提高自己的编程水平，如果你仔细研究copr ...

我用了你修正后的函数，传递汉字时，变成乱码。

tubaba

smooth 发表于 2022-5-27 14:46
我用了你修正后的函数，传递汉字时，变成乱码。

我不知道你乱码是怎么产生的,WM_COPYDATA函数也是比较可靠的,还是那句话,有问题很正常,问题是怎么产生的,自己多思考,别人只能给你抛砖引玉,不会给你具体的代码实现

#include <GuiEdit.au3>
Global $My_Hwnd = GUICreate("WM_COPYDATA接收", 300, 600, @DesktopWidth / 2 - 300, Default, Default, 0x00000008)
$ssss= GUICtrlCreateEdit('', 5,5,280,400)
GUIRegisterMsg(0x004A, "WM_COPYDATA")
GUISetState()
Run(StringFormat('"%s" "%s" "%s"',@AutoItExe,@ScriptDir & '\WM_COPYDATA发送.au3',String($My_Hwnd)))


Do
Until GUIGetMsg() = -3



Func WM_COPYDATA($hWnd, $Msg, $wParam, $lParam)
        #forceref $hWnd, $Msg, $wParam, $lParam
        Local $COPYDATA, $tMyData, $MyData
        $COPYDATA = DllStructCreate("ptr;dword;ptr", $lParam)
        $tMyData = DllStructCreate("byte[" & DllStructGetData($COPYDATA, 2) & "]", DllStructGetData($COPYDATA, 3))
        $MyData = BinaryToString(DllStructGetData($tMyData, 1), 4)
        _GUICtrlEdit_AppendText($ssss, $MyData & @CRLF)
        Return 
EndFunc   ;==>WM_COPYDATA

#include <GuiEdit.au3>
Global $hWndTarget
Global $WM_COPYDATA = 0x004A
If $cmdline[0] = 1 Then
$hWndTarget = HWnd($cmdline[1])
Else
        Exit MsgBox(0,1,'请先运行接收端')
EndIf
Global $My_Hwnd = GUICreate("WM_COPYDATA发送", 300, 600,  @DesktopWidth / 2 + 5, Default, Default, 0x00000008)
$ssss= GUICtrlCreateEdit('', 5,5,280,400)

$bbbb = GUICtrlCreateButton('请直接点击', 10, 450, 100, 30)

GUISetState()


While 1
        $msg = GUIGetMsg()
        Switch $msg
                Case -3
                        Exit
                Case $bbbb

                        For $i = 129 To 131
                                For $j = 64 To 254
                                        Local $code = Hex($i, 2) & Hex($j, 2)
                                        Local $str = BinaryToString('0x' & $code)
                                        If $j <> 127 Then _GUICtrlEdit_AppendText($ssss, '"' & $str & '","' & $code & '"')
                                        SendData($hWndTarget, '"' & $str & '","' & $code & '"')
                                Next
                                If $i <> 87 Then _GUICtrlEdit_AppendText($ssss, @CRLF)
                                SendData($hWndTarget, @CRLF)        
                        Next


        EndSwitch
WEnd


Func SendData($hWndTarget, $sData)
                Local $msg = StringToBinary($sData, 4) 
                Local $MyData = DllStructCreate("byte[" & BinaryLen($msg) & "]")
                Local $COPYDATA = DllStructCreate("ptr;dword;ptr")
                DllStructSetData($MyData, 1, $msg)
                DllStructSetData($COPYDATA, 1, 0)
                DllStructSetData($COPYDATA, 2, DllStructGetSize($MyData))
                DllStructSetData($COPYDATA, 3, DllStructGetPtr($MyData))
                
                Local $aTmp = DllCall("user32.dll", "int", "SendMessageTimeout", "hwnd", $hWndTarget, "int", $WM_COPYDATA _ ; WM_COPYDATA
                                , "int", 0, "ptr", DllStructGetPtr($COPYDATA), "int", 0, "int", 1000, "long*", 0)
EndFunc   ;==>SendSciTE_Command

tubaba

smooth 发表于 2022-5-25 17:15
请教一下，发送消息的时候，为何要创建两个数据结构，我看着感觉创建一个数据结构，就可以把数据传递过去 ...

因为copydata就是这个结构啊,这是官方定义的